Messaggi personalizzati in classi non-Windowed - bisogno di un gestore predefinito?

Question

con una classe (TObject) ho:

private 
    FHwnd : HWND; 
    procedure HandleMyMessage(var Message : TMessage); message TH_MYMESSAGE; 

dove TH_MYMESSAGE = WM_USER + 1

nel costruttore della classe:

FHwnd := AllocateHWND(HandleMyMessage); 

L'unico oggetto che riceve un riferimento a FHwnd è una consuetudine privata TThread (creato all'interno di questa classe) e l'unico messaggio che invia è TH_MYMESSAGE. La mia comprensione è che la direttiva message nella dichiarazione di procedura limita la sua gestione solo a TH_MYMESSAGE.

Questo stava funzionando bene nei test, ma dopo l'integrazione in un'applicazione molto più grande sto ricevendo il feedback che HandleMyMessage si attiva anche per altri messaggi (con evidenti risultati indesiderati).

Questo è stato facilmente corretto aggiungendo if Message.Msg <> TH_MYMESSAGE then Exit; in HandleMyMessage. La mia domanda è: perché sta succedendo questo?

La mia ipotesi migliore è che AllocateHWND abbia reso HandleMyMessage l'equivalente di un DefWndProc nonostante abbia la direttiva message. C'è un modo corretto per implementare questo che mi manca?

Answer 1

Beh, sì certo. AllocateHWnd accetta un TWndMethod per agire come la procedura della finestra della finestra creata. La confusione, credo, è causata dal fatto che il compilatore accetta la direttiva messsage. Non metterlo:

private 
    FHwnd : HWND; 
    procedure HandleMyMessage(var Message : TMessage); 

.. 

procedure TMyClass.HandleMyMessage(var Message: TMessage); 
begin 
    case Message.Msg of 
    TH_MYMESSAGE: // 
    end; 
    Message.Result := DefWindowProc(FHWnd, Message.Msg, Message.WParam, Message.LParam); 
end; 

---

edit: (risposta al commento). Per avere il messaggio gestito sulla classe che ha creato la finestra di utilità, è possibile instradare il messaggio dalla finestra AllocateHWnd crea alla classe:

private 
    FHwnd : HWND; 
    procedure HandleMyMessage(var Message : TMessage); 
    procedure THMyMessage(var Message: TMessage); message TH_MYMESSAGE; 

.. 

procedure TMyClass.HandleMyMessage(var Message: TMessage); 
begin 
    case Message.Msg of 
    TH_MYMESSAGE: Dispatch(Message); 
    end; 
    Message.Result := DefWindowProc(FHWnd, Message.Msg, Message.WParam, Message.LParam); 
end; 

procedure TMyClass.THMyMessage(var Message: TMessage); 
begin 
    // 
end;