Come posso impostare/ottenere il valore della proprietà tramite RTTI per oggetti compex come TStringGrid.Cells?

Question

I valori sono memorizzati in codice xml e lua e accesso alle proprietà dell'oggetto tramite RTTI.

var 
    o, v: TValue; // o is current object 
    a: TStringDynArray; // params as array 
    ctx: TRttiContext; 
    tt: TRttiType; 
    p: TRttiProperty; 
    pt: PTypeInfo; 
begin 
... 
    ctx := TRttiContext.Create; 
    try 
    o := GetLastClassInParams(ctx, obj, a, param_idx); 
    tt := ctx.GetType(o.TypeInfo); 
    if high(a) < param_idx then 
     raise Exception.Create(S_FN + S_NOP); 
    p := tt.GetProperty(a[param_idx]); 
    if p = nil then 
     raise Exception.Create(S_FN + S_PNE + a[param_idx]); 
    pt := p.PropertyType.Handle; 
    case p.PropertyType.TypeKind of 
     tkInteger: v := TValue.From<integer>(integer(Value)); 
     tkEnumeration: v := TValue.FromOrdinal(pt, GetEnumValue(pt, VarToStr(Value))); 
     tkUString: v := TValue.From<string>(VarToStr(Value)); 
     tkFloat: v := TValue.From<double>(double(Value)); 
     tkSet: begin 
      temp_int := StringToSet(pt, VarToStr(Value)); 
      TValue.Make(@temp_int, pt, v); 
     end; 
    else v := TValue.FromVariant(Value); 
    end; 
    p.SetValue(o.AsObject, v); 

posso lavorare con molte proprietà come Width, Lines.Text di TMemo ecc, anche con Panels[0].Width di TStatusBar (in cui i pannelli è TCollection discendente), ma cosa come TStringGrid.Cells[x, y] è qualcosa che non riesco a risolvere. C'è aiuto su Embarcadero e alcune funzioni come GetIndexedProperty (forse è quello che mi serve), ma la spiegazione è valida come "Gets Indexed Property".

Come impostare e ottenere TStringGrid.Cells[x,y] tramite RTTI in fase di esecuzione se i valori sono memorizzati come stringhe come "Cells[1,1]"?

Answer 1

Ecco l'esempio più semplice che posso pensare fuori per ottenere e impostare i valori da una griglia stringa utilizzando RTTI:

var 
    ctx: TRttiContext; 
    rttitype: TRttiType; 
    rttiprop: TRttiIndexedProperty; 
    value: TValue; 
.... 
rttitype := ctx.GetType(StringGrid1.ClassType); 
rttiprop := rttitype.GetIndexedProperty('Cells'); 
value := rttiprop.GetValue(StringGrid1, [1, 1]); 
rttiprop.SetValue(StringGrid1, [1, 1], value.ToString + ' hello'); 

ho asportato il controllo degli errori per semplicità. Presumo che tu sappia già come controllare gli errori.