aggancio eval-after-load vs. mode

Question

C'è una differenza tra l'impostazione di una modalità usando eval-after-load e l'utilizzo del hook della modalità?

Ho visto un codice in cui define-key viene utilizzato all'interno di un hook di modalità principale e un altro codice in cui define-key viene utilizzato nel modulo eval-after-load.

---

Aggiornamento:

Per una migliore comprensione, ecco un esempio di utilizzo eval-post-carico e ganci modalità con org-mode. Il codice può essere eseguito prima del(load "org") o (require 'org) o (package-initialize).

;; The following two lines of code set some org-mode options. 
;; Usually, these can be outside (eval-after-load ...) and work. 
;; In cases that doesn't work, try using setq-default or set-variable 
;; and putting them in (eval-after-load ...), if the 
;; doc for the variables don't say what to do. 
;; Or use Customize interface. 
(setq org-hide-leading-stars t) 
(setq org-return-follows-link t) 

;; "org" because C-h f org-mode RET says that org-mode is defined in org.el 
(eval-after-load "org" 
    '(progn 
    ;; Establishing your own keybindings for org-mode. 
    ;; Variable org-mode-map is available only after org.el or org.elc is loaded. 
    (define-key org-mode-map (kbd "<C-M-return>") 'org-insert-heading-respect-content) 
    (define-key org-mode-map (kbd "<M-right>") nil) ; erasing a keybinding. 
    (define-key org-mode-map (kbd "<M-left>") nil) ; erasing a keybinding. 

    (defun my-org-mode-hook() 
     ;; The following two lines of code is run from the mode hook. 
     ;; These are for buffer-specific things. 
     ;; In this setup, you want to enable flyspell-mode 
     ;; and run org-reveal for every org buffer. 
     (flyspell-mode 1) 
     (org-reveal)) 
    (add-hook 'org-mode-hook 'my-org-mode-hook))) 

Answer 1

Codice avvolto in eval-after-load verrà eseguito solo una volta, per cui è in genere utilizzato per eseguire l'impostazione di una volta come l'impostazione dei valori predefiniti globali e comportamento. Un esempio potrebbe essere la configurazione di una keymap predefinita per una modalità particolare. Nel codice eval-after-load, non esiste il concetto di "buffer corrente".

I hook di modalità vengono eseguiti una volta per ogni buffer in cui è abilitata la modalità, quindi vengono utilizzati per la configurazione per buffer. I ganci Mode vengono quindi eseguiti dopo il codice eval-after-load; ciò consente loro di intraprendere azioni basate su tali informazioni come se altre modalità siano abilitate nel buffer corrente.