Come usare awk per estrarre un campo quotato?

Question

Sto usando

awk '{ printf "%s", $3 }' 

di estrarre qualche campo da una linea di spazio delimitato. Naturalmente ottengo risultati parziali quando il campo è quotato con spazi liberi all'interno. Qualcuno può suggerire una soluzione per favore?

Answer 1

Questo è in realtà piuttosto difficile. Ho trovato il seguente script awk che divide la linea manualmente e memorizza tutti i campi in una matrice.

{ 
    s = $0 
    i = 0 
    split("", a) 
    while ((m = match(s, /"[^"]*"/)) > 0) { 
     # Add all unquoted fields before this field 
     n = split(substr(s, 1, m - 1), t) 
     for (j = 1; j <= n; j++) 
      a[++i] = t[j] 
     # Add this quoted field 
     a[++i] = substr(s, RSTART + 1, RLENGTH - 2) 
     s = substr(s, RSTART + RLENGTH) 
     if (i >= 3) # We can stop once we have field 3 
      break 
    } 
    # Process the remaining unquoted fields after the last quoted field 
    n = split(s, t) 
    for (j = 1; j <= n; j++) 
     a[++i] = t[j] 
    print a[3] 
} 

Answer 2

visualizza il file di input e l'output desiderato la volta successiva. Per ottenere campi tra virgolette,

$ cat file 
field1 field2 "field 3" field4 "field5" 

$ awk -F'"' '{for(i=2;i<=NF;i+=2) print $i}' file 
field 3 
field5 

Answer 3

Ecco una possibile soluzione alternativa a questo problema. Funziona trovando i campi che iniziano o terminano con le virgolette, e quindi unendoli tra loro. Alla fine aggiorna i campi e NF, quindi se metti più pattern dopo quello che fa l'unione, puoi elaborare i (nuovi) campi usando tutte le normali funzioni di awk.

Penso che questo usi solo le funzioni di POSIX awk e non si basa sulle estensioni di gawk, ma non ne sono completamente sicuro.

# This function joins the fields $start to $stop together with FS, shifting 
# subsequent fields down and updating NF. 
# 
function merge_fields(start, stop) { 
    #printf "Merge fields $%d to $%d\n", start, stop; 
    if (start >= stop) 
     return; 
    merged = ""; 
    for (i = start; i <= stop; i++) { 
     if (merged) 
      merged = merged OFS $i; 
     else 
      merged = $i; 
    } 
    $start = merged; 

    offs = stop - start; 
    for (i = start + 1; i <= NF; i++) { 
     #printf "$%d = $%d\n", i, i+offs; 
     $i = $(i + offs); 
    } 
    NF -= offs; 
} 

# Merge quoted fields together. 
{ 
    start = stop = 0; 
    for (i = 1; i <= NF; i++) { 
     if (match($i, /^"/)) 
      start = i; 
     if (match($i, /"$/)) 
      stop = i; 
     if (start && stop && stop > start) { 
      merge_fields(start, stop); 
      # Start again from the beginning. 
      i = 0; 
      start = stop = 0; 
     } 
    } 
} 

# This rule executes after the one above. It sees the fields after merging. 
{ 
    for (i = 1; i <= NF; i++) { 
     printf "Field %d: >>>%s<<<\n", i, $i; 
    } 
} 

Su un file di input come:

thing "more things" "thing" "more things and stuff" 

produce:

Field 1: >>>thing<<< 
Field 2: >>>"more things"<<< 
Field 3: >>>"thing"<<< 
Field 4: >>>"more things and stuff"<<< 

Answer 4

Se siete solo in cerca di un campo specifico poi

$ cat file 
field1 field2 "field 3" field4 "field5" 

awk -F"\"" '{print $2}' file 

opere. Divide il file per ", quindi il secondo campo nell'esempio sopra è quello desiderato.