Unire due liste in Haskell

Question

non riesce a capire come unire due liste nel seguente modo in Haskell:

INPUT: [1,2,3,4,5] [11,12,13,14] 

OUTPUT: [1,11,2,12,3,13,4,14,5] 

Answer 1

merge :: [a] -> [a] -> [a] 
merge xs  []  = xs 
merge []  ys  = ys 
merge (x:xs) (y:ys) = x : y : merge xs ys 

Answer 2

EDIT: Date un'occhiata a risposta e commenti di Ed'ka !

Altra possibilità:

merge xs ys = concatMap (\(x,y) -> [x,y]) (zip xs ys) 

O, se vi piace applicativo:

merge xs ys = concat $ getZipList $ (\x y -> [x,y]) <$> ZipList xs <*> ZipList ys 

Answer 3

Allora perché pensi così semplice (. Concat trasposizione) "non è abbastanza carina"? Presumo che hai provato qualcosa di simile:

merge :: [[a]] -> [a] 
merge = concat . transpose 

merge2 :: [a] -> [a] -> [a] 
merge2 l r = merge [l,r] 

questo modo si può evitare la ricorsione esplicita (vs la prima risposta) e ancora è più semplice rispetto alla seconda risposta. Quindi quali sono gli svantaggi?

Answer 4

vi voglio proporre una versione più pigri di unione:

merge [] ys = ys 
merge (x:xs) ys = x:merge ys xs 

Per un caso di esempio, l'utilizzo è possibile controllare una recente domanda SO su lazy generation of combinations.
La versione nella risposta accettata è inutilmente severa nel secondo argomento ed è ciò che è migliorato qui.

Answer 5

-- ++ 
pp [] [] = [] 
pp [] (h:t) = h:pp [] t 
pp (h:t) [] = h:pp t [] 
pp (h:t) (a:b) = h : pp t (a:b) 

Answer 6

Sicuramente un caso per un unfold:

interleave :: [a] -> [a] -> [a] 
interleave = curry $ unfoldr g 
    where 
    g ([], []) = Nothing 
    g ([], (y:ys)) = Just (y, (ys, [])) 
    g (x:xs, ys) = Just (x, (ys, xs))