Desidero creare un programma di installazione NSIS che controlli .NET Framework e lo installi se non è presente. Puoi indicarmi una sceneggiatura per questo? Sono molto nuovo con NSIS.Programma di installazione NSIS che verifica .NET Framework
!define DOT_MAJOR "2"
!define DOT_MINOR "0"
Function IsDotNetInstalled
StrCpy $0 "0"
StrCpy $1 "SOFTWARE\Microsoft\.NETFramework" ;registry entry to look in.
StrCpy $2 0
StartEnum:
;Enumerate the versions installed.
EnumRegKey $3 HKLM "$1\policy" $2
;If we don't find any versions installed, it's not here.
StrCmp $3 "" noDotNet notEmpty
;We found something.
notEmpty:
;Find out if the RegKey starts with 'v'.
;If it doesn't, goto the next key.
StrCpy $4 $3 1 0
StrCmp $4 "v" +1 goNext
StrCpy $4 $3 1 1
;It starts with 'v'. Now check to see how the installed major version
;relates to our required major version.
;If it's equal check the minor version, if it's greater,
;we found a good RegKey.
IntCmp $4 ${DOT_MAJOR} +1 goNext yesDotNetReg
;Check the minor version. If it's equal or greater to our requested
;version then we're good.
StrCpy $4 $3 1 3
IntCmp $4 ${DOT_MINOR} yesDotNetReg goNext yesDotNetReg
goNext:
;Go to the next RegKey.
IntOp $2 $2 + 1
goto StartEnum
yesDotNetReg:
;Now that we've found a good RegKey, let's make sure it's actually
;installed by getting the install path and checking to see if the
;mscorlib.dll exists.
EnumRegValue $2 HKLM "$1\policy\$3" 0
;$2 should equal whatever comes after the major and minor versions
;(ie, v1.1.4322)
StrCmp $2 "" noDotNet
ReadRegStr $4 HKLM $1 "InstallRoot"
;Hopefully the install root isn't empty.
StrCmp $4 "" noDotNet
;build the actuall directory path to mscorlib.dll.
StrCpy $4 "$4$3.$2\mscorlib.dll"
IfFileExists $4 yesDotNet noDotNet
noDotNet:
;Nope, something went wrong along the way. Looks like the proper .NETFramework isn't installed.
Push "NOK"
Return
yesDotNet:
;Everything checks out. Go on with the rest of the installation.
Push "OK"
Return
FunctionEnd
Il seguente codice controlla se .Net 3.5 è installato e, in caso contrario, lo installerà in silenzio. Usa una macro che verifica che esista una chiave specificata nel registro.
La macro:
# This macro checks if a certain key exists in the registry
!macro IfKeyExists ROOT MAIN_KEY KEY
push $R0
push $R1
!define Index 'Line${__LINE__}'
StrCpy $R1 "0"
"${Index}-Loop:"
; Check for Key
EnumRegKey $R0 ${ROOT} "${MAIN_KEY}" "$R1"
StrCmp $R0 "" "${Index}-False"
IntOp $R1 $R1 + 1
StrCmp $R0 "${KEY}" "${Index}-True" "${Index}-Loop"
"${Index}-True:"
;Return 1 if found
push "1"
goto "${Index}-End"
"${Index}-False:"
;Return 0 if not found
push "0"
goto "${Index}-End"
"${Index}-End:"
!undef Index
exch 2
pop $R0
pop $R1
!macroend
La funzione:
# The function that checks if .net is already installed
Function CheckDotNet
!insertmacro IfKeyExists HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall" "{CE2CDD62-0124-36CA-84D3-9F4DCF5C5BD9}"
Pop $R0
${If} $R0 == 0 # not installed NOTE: /q:a means this will be a silent installation
ExecWait "$EXEDIR\dotnetfx35.exe /q:a"
Goto endPrerequisites
${EndIf}
endPrerequisites:
# Code to execute after checking/installing (if necessary) .Net
# You can just put "Goto +2" here, in order to go to the next section/function
FunctionEnd
Affinché questo funzioni, si deve chiamare CheckDotNet da qualche parte nella funzione .onInit e fare in modo che dotnetfx35.exe è incluso nel tuo installer nello $EXEDIR (ovviamente puoi cambiare e parametri come preferisci).
Per le altre versioni di Net, suppongo l'unica cosa diversa sarà la chiave di registro specificato nel parametro macro IfKeyExists (ora è {CE2CDD62-0124-36CA-84D3-9F4DCF5C5BD9})
ReadRegDWORD $0 HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v4\Client" Install
Poi si dovrebbe verificare $0. Sta a te come.
Che cosa ritieni che questo aggiunga rispetto alle altre risposte? Non dice quello che dovrebbe essere, né lo installa. –
ho avuto un problema con il pluging "DotNET.nsh", che potete trovare somwhere, e semplicemente utilizzato questa soluzione (per NET 4.0, installazione completa - che mi serviva, si può anche limitare a il pacchetto client):
ClearErrors
ReadRegDWORD $0 HKLM "Software\Microsoft\Net Framework Setup\NDP\v4\Full" "Install"
IfErrors dotNet40NotFound
IntCmp $0 1 dotNet40Found
dotNet40NotFound:
Banner::show /set 76 "Installing .NET Framework 4.0" "Please wait"
File /nonfatal "tools\dotNetFx40_Full_setup.exe"
; if you don't have $TEMP already, add here:
; SetOutPath $TEMP
ExecWait "$TEMP\dotNetFx40_Full_setup.exe /passive /norestart"
Delete /REBOOTOK "$TEMP\dotNetFx40_Full_setup.exe"
Banner::destroy
dotNet40Found:
la roba banner è facoltativa, si potrebbe utilizzare DetailPrint o simili. In questo modo, si trascina il programma di installazione Web per .NET 4.0, ma è piuttosto piccolo (a differenza delle versioni .NET che non ne avevano uno). L'installer esegue il download se necessario e non sono necessari chilometri di codice NSIS.
Probabilmente non è la ragione giusta per un upvote, ma questo codice di script ha più senso per me di qualsiasi altro esempio di questo. Grazie. –
Provare lo script DotNetVer. Utilizza LogicLib ed è abbastanza facile da usare.
Esempio:
${If} ${HasDotNet4.0}
DetailPrint "Microsoft .NET Framework 4.0 installed."
${If} ${DOTNETVER_4_0} AtLeastDotNetServicePack 1
DetailPrint "Microsoft .NET Framework 4.0 is at least SP1."
${Else}
DetailPrint "Microsoft .NET Framework 4.0 SP1 not installed."
${EndIf}
${If} ${DOTNETVER_4_0} HasDotNetClientProfile 1
DetailPrint "Microsoft .NET Framework 4.0 (Client Profile) available."
${EndIf}
${If} ${DOTNETVER_4_0} HasDotNetFullProfile 1
DetailPrint "Microsoft .NET Framework 4.0 (Full Profile) available."
${EndIf}
${If} ${DOTNETVER_4_0} HasDotNetFullProfile 0
DetailPrint "Microsoft .NET Framework 4.0 (Full Profile) not available."
${EndIf}
${EndIf}
Se siete alla ricerca di opzioni con NET Framework 4.0+ (e sopra) compreso
controllare questo plug-in per NSIS: DotNetChecker
Hmm, questo mi interessa anche a me! –
Esistono diversi esempi nel [wiki NSIS] (http://nsis.sourceforge.net/Main_Page). Prova [questo] (http://nsis.sourceforge.net/DotNET). –
Ecco il modo per verificare quale versione è installata provatela http://forums.winamp.com/showthread.php?t=324928 – dastanko