Come ottenere informazioni sul computer? [32 bit o 64 bit]

Question

Come posso ottenere informazioni sul tipo di sistema operativo Windows? È a 32 bit o 64 bit? Come posso ottenere queste informazioni in modo programmatico?

Answer 1

è necessario utilizzare GetProcAddress() per verificare la disponibilità della funzione IsWow64Process() in fase di esecuzione, in questo modo:

function Is64BitWindows: boolean; 
type 
    TIsWow64Process = function(hProcess: THandle; var Wow64Process: BOOL): BOOL; 
    stdcall; 
var 
    DLLHandle: THandle; 
    pIsWow64Process: TIsWow64Process; 
    IsWow64: BOOL; 
begin 
    Result := False; 
    DllHandle := LoadLibrary('kernel32.dll'); 
    if DLLHandle <> 0 then begin 
    pIsWow64Process := GetProcAddress(DLLHandle, 'IsWow64Process'); 
    Result := Assigned(pIsWow64Process) 
     and pIsWow64Process(GetCurrentProcess, IsWow64) and IsWow64; 
    FreeLibrary(DLLHandle); 
    end; 
end; 

perché questa funzione è disponibile solo sulle versioni di Windows che hanno un sapore a 64 bit. Dichiarandolo come external si impedisce l'esecuzione dell'applicazione su Windows 2000 o Windows XP pre SP2.

Edit:

Chris ha pubblicato un commento sulla memorizzazione nella cache il risultato per motivi di prestazioni. Questo potrebbe non essere necessario per questa particolare funzione API, perché kernel32.dll sarà sempre lì (e non riesco a immaginare un programma che potrebbe caricare anche senza di esso), ma per altre funzioni le cose potrebbero essere diverse. Quindi, ecco una versione che memorizza nella cache il risultato della funzione:

function Is64BitWindows: boolean; 
type 
    TIsWow64Process = function(hProcess: THandle; var Wow64Process: BOOL): BOOL; 
    stdcall; 
var 
    DLLHandle: THandle; 
    pIsWow64Process: TIsWow64Process; 
const 
    WasCalled: BOOL = False; 
    IsWow64: BOOL = False; 
begin 
    if not WasCalled then begin 
    DllHandle := LoadLibrary('kernel32.dll'); 
    if DLLHandle <> 0 then begin 
     pIsWow64Process := GetProcAddress(DLLHandle, 'IsWow64Process'); 
     if Assigned(pIsWow64Process) then 
     pIsWow64Process(GetCurrentProcess, IsWow64); 
     WasCalled := True; 
     FreeLibrary(DLLHandle); 
    end; 
    end; 
    Result := IsWow64; 
end; 

Caching questo risultato funzione è sicuro, in quanto la funzione API o sarà lì o no, e il suo risultato non può cambiare sulla stessa installazione di Windows. È anche sicuro chiamarlo contemporaneamente da più thread, poiché due thread che trovano WasCalled da False chiameranno entrambi la funzione, scrivono lo stesso risultato nella stessa posizione di memoria e solo dopo impostano WasCalled in True.

Answer 2

Se a) si è su windows eb) è possibile accedere al registro quindi HKEY_LOCAL_MACHINE \ SOFTWARE \ Microsoft \ Windows NT \ CurrentVersion dovrebbe essere informativo.

Answer 3

Non so come chiamare la funzione Win32 in Delphi.

Ma se si scrive un programma a 32 bit, è possibile chiamare l'API Win32 IsWow64Process per sapere se ci si trova in un sistema operativo a 64 bit.

Ovviamente, se si scrive un exe a 64 bit, verrà eseguito solo su Windows a 64 bit, quindi non è necessario chiedere.

Answer 4

function IsWin64: Boolean; 
var 
    IsWow64Process : function(hProcess : THandle; var Wow64Process : BOOL): BOOL; stdcall; 
    Wow64Process : BOOL; 
begin 
    Result := False; 
    IsWow64Process := GetProcAddress(GetModuleHandle(Kernel32), 'IsWow64Process'); 
    if Assigned(IsWow64Process) then begin 
    if IsWow64Process(GetCurrentProcess, Wow64Process) then begin 
     Result := Wow64Process; 
    end; 
    end; 
end; 

Answer 5

Oltre a IsWow64Process, la funzione GetNativeSystemInfo API possono essere di interesse per voi (è definito nell'unità Windows) per scoprire di più sulla CPU si è in (oppure si può utilizzare il montaggio e CPUID).

Answer 6

// non testati, ma u può provare questo

is64 := (Environment.GetEnvironmentVariable('ProgramW6432') <> ''); 

Answer 7

per Delphi XE +

Uses System.SysUtils 

Function IsWin64Or32: string; 
Begin 
    if Pos('64-bit', TOSVersion.ToString) > 0 then 
    Result := '64-bit' 
    Else 
    Result := '32-bit'; 
End; 

Esempio

lbl1.Caption := IsWin64Or32; 

Answer 8

function TForm2.Arch: string; 
begin 
if TOSVersion.Architecture=arIntelX86 then 
    Result := '32-bit' Else Result := '64-bit' 
end;