VBA Come forzare una funzione a ritornare quando si preme un pulsante di forma

Question

Ho pensato che sarebbe stato semplice, ma si sta dimostrando piuttosto difficile. Qualsiasi consiglio o idea sarebbe appretiato.

Ho un modulo in Excel che se si preme un determinato pulsante, ho bisogno che l'utente inserisca una password prima che venga eseguito il codice per quel pulsante.

ho potuto solo usare un InputBox, ma che permetterà a nessuno di vedere la password quando viene digitato. Quindi voglio utilizzare un secondo modulo con una casella di testo e impostare è il parametro PasswordChar a *

Qui è il problema Voglio usare il codice come questo

if checkPassword("Please enter your password") = False then exit sub 

checkPassword è una funzione che prende una stringa come parametro. Questa funzione apre un modulo e inserisce il messaggio in un'etichetta. L'utente deve inserire la password e fare clic su OK.

il sub btnOK_Click() deve verificare che la password sia corretta e quindi forzare la funzione che ha aperto il modulo per restituire True se la password era OK o False è la password non corretta.

Non riesco a capire come forzare la funzione a tornare. Ho provato a impostare una variabile globale su True o False quando l'utente fa clic su OK e quindi scarica il modulo. Ciò rende il Function restituito, ma reimposta anche tutte le variabili globali impostate dal modulo.

Qui è la mia funzione che chiama la forma

Function checkPassword(message As String) As Boolean 

    frmPassword.Show 
    frmPassword.passwordMsg.Caption = message 

    'passwordStatus is a global variable 
    If passwordStatus = True Then checkPassword = True Else checkPassword = False 

End Function 

Ecco il sub collegato al pulsante forme OK:

Private Sub passwordok_Click() 

    If Me.passwordtext.Text = "password" Then 
     passwordStatus = True 
    Else 
     passwordStatus = False 
    End If 
    Unload Me 

End Sub 

Answer 1

Restituzione di un valore da una finestra di dialogo è un compito comune & abbastanza semplice da fare.

Il modello più semplice consiste nel mettere la funzione nella forma di dialogo stessa e fare in modo che la funzione mostri la sua forma host in modo modale.

Private passwordStatus As Boolean 

Function checkPassword(message As String) As Boolean 
    '//setup the form 
    Me.passwordMsg.Caption = message 

    '//show the form modally, this will not return until the form is unloaded 
    '//i.e. when the button is clicked; so values in private variable are still valid 
    Me.Show vbModal 

    '//form is unloaded (via unload me or a close) return the value; 
    checkPassword = passwordStatus 
End Function 

Private Sub passwordok_Click() 
    passwordStatus = Me.passwordtext.Text = "password" 
    Unload Me 
End Sub 

utilizzato come

passworkOk = frmPassword.checkPassword("enter your blabla") 

Answer 2

ho potuto solo usare un inputbox, ma questo permetterà a chiunque altro di vedere la password quando viene digitata. Quindi voglio usare un secondo modulo con una casella di testo e impostare il suo parametro PasswordChar su *

Ecco qualcosa dal mio database.

NEGAZIONE: non ho scritto QUESTO E NON RICORDO che ha scritto questo

USO:

Private Sub passwordok_Click() 
    Dim Prompt, password As String 
    Prompt = "Please enter your password." 
    password = InputBoxDK(Prompt) 

    MsgBox password '<~~ Do whatever you want to do with this 
End Sub 

in un modulo

Option Explicit 

Private Declare Function CallNextHookEx Lib "user32" (ByVal hHook As Long, _ 
ByVal ncode As Long, ByVal wParam As Long, lParam As Any) As Long 

Private Declare Function GetModuleHandle Lib "kernel32" Alias _ 
"GetModuleHandleA" (ByVal lpModuleName As String) As Long 

Private Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" _ 
(ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, _ 
ByVal dwThreadId As Long) As Long 

Private Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hHook As Long) As Long 

Private Declare Function SendDlgItemMessage Lib "user32" Alias "SendDlgItemMessageA" _ 
(ByVal hDlg As Long, ByVal nIDDlgItem As Long, ByVal wMsg As Long, _ 
ByVal wParam As Long, ByVal lParam As Long) As Long 

Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" _ 
(ByVal hwnd As Long, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long 

Private Declare Function GetCurrentThreadId Lib "kernel32"() As Long 

'Constants to be used in our API functions 
Private Const EM_SETPASSWORDCHAR = &HCC 
Private Const WH_CBT = 5 
Private Const HCBT_ACTIVATE = 5 
Private Const HC_ACTION = 0 

Private hHook As Long 

Public Function NewProc(ByVal lngCode As Long, ByVal wParam As Long, _ 
ByVal lParam As Long) As Long 
    Dim RetVal 
    Dim strClassName As String, lngBuffer As Long 

    If lngCode < HC_ACTION Then 
     NewProc = CallNextHookEx(hHook, lngCode, wParam, lParam) 
     Exit Function 
    End If 

    strClassName = String$(256, " ") 
    lngBuffer = 255 

    'A window has been activated 
    If lngCode = HCBT_ACTIVATE Then 
     RetVal = GetClassName(wParam, strClassName, lngBuffer) 
     'Class name of the Inputbox 
     If Left$(strClassName, RetVal) = "#32770" Then 
      'This changes the edit control so that it display the password character *. 
      'You can change the Asc("*") as you please. 
      SendDlgItemMessage wParam, &H1324, EM_SETPASSWORDCHAR, Asc("*"), &H0 
     End If 
    End If 

    'This line will ensure that any other hooks that may be in place are 
    'called correctly. 
    CallNextHookEx hHook, lngCode, wParam, lParam 

End Function 

Public Function InputBoxDK(Prompt, Optional Title, Optional Default, Optional XPos, _ 
Optional YPos, Optional HelpFile, Optional Context) As String 
    Dim lngModHwnd As Long, lngThreadID As Long 
    lngThreadID = GetCurrentThreadId 
    lngModHwnd = GetModuleHandle(vbNullString) 
    hHook = SetWindowsHookEx(WH_CBT, AddressOf NewProc, lngModHwnd, lngThreadID) 
    InputBoxDK = InputBox(Prompt, Title, Default, XPos, YPos, HelpFile, Context) 
    UnhookWindowsHookEx hHook 
End Function 

SNAPSHOT