Come attivare un effetto vetro (Windows Vista/7) in un'applicazione console usando Delphi

Question

Come posso attivare l'effetto vetro sulle mie applicazioni console. Sto usando Windows 7 e Delphi 2010.

Ho trovato l'applicazione this quindi dovrebbe essere possibile.

Answer 1

Un paio di settimane fa ho pubblicato this article sul mio blog.

La chiave utilizza le funzioni e DwmEnableBlurBehindWindow.

La funzione GetConsoleWindow recupera l'handle di finestra utilizzato dalla console associata al processo chiamante.

La funzione DwmEnableBlurBehindWindow attiva l'effetto sfocatura (vetro) sulla maniglia della finestra fornita.

program ConsoleGlassDelphi; 

{$APPTYPE CONSOLE} 

    uses 
    Windows, 
    SysUtils; 

type 
    DWM_BLURBEHIND = record 
    dwFlags     : DWORD; 
    fEnable     : BOOL; 
    hRgnBlur    : HRGN; 
    fTransitionOnMaximized : BOOL; 
    end; 

function DwmEnableBlurBehindWindow(hWnd : HWND; const pBlurBehind : DWM_BLURBEHIND) : HRESULT; stdcall; external 'dwmapi.dll' name 'DwmEnableBlurBehindWindow';//function to enable the glass effect 
function GetConsoleWindow: HWND; stdcall; external kernel32 name 'GetConsoleWindow'; //get the handle of the console window 

function DWM_EnableBlurBehind(hwnd : HWND; AEnable: Boolean; hRgnBlur : HRGN = 0; ATransitionOnMaximized: Boolean = False; AFlags: Cardinal = 1): HRESULT; 
var 
    pBlurBehind : DWM_BLURBEHIND; 
begin 
    pBlurBehind.dwFlags:=AFlags; 
    pBlurBehind.fEnable:=AEnable; 
    pBlurBehind.hRgnBlur:=hRgnBlur; 
    pBlurBehind.fTransitionOnMaximized:=ATransitionOnMaximized; 
    Result:=DwmEnableBlurBehindWindow(hwnd, pBlurBehind); 
end; 

begin 
    try 
    DWM_EnableBlurBehind(GetConsoleWindow(), True); 
    Writeln('See my glass effect'); 
    Writeln('Go Delphi Go'); 
    Readln; 
    except 
    on E:Exception do 
     Writeln(E.Classname, ': ', E.Message); 
    end; 
end. 

Questo è solo un esempio di base; è necessario verificare la versione del sistema operativo Windows per evitare problemi.