Posso abbinare un carattere jolly del costruttore di dati in Haskell?

Question

Ho

data Foo = X (String, Int) | A String | B String | C String | D String -- ... 

e ho definito

f (X (s, _)) =s 
f (A s) = s 
f (B s) = s 
f (C s) = s 
f (D s) = s 
-- ... 

ma preferirei essere in grado di scrivere qualcosa di simile

f (X (s, _)) =s 
f (_ s) = s 

Ma sembra che ci sia alcun modo per farlo (I ottenere un "errore di analisi" associato allo _).

Esiste un modo per associare un carattere jolly del costruttore di dati in Haskell?

Answer 1

No. Ma puoi scrivere questo:

data Foo 
    = X { name :: String, age :: Int } 
    | A { name :: String } 
    | B { name :: String } 
    | C { name :: String } 
    | D { name :: String } 

e quindi avere name :: Foo -> String. Si potrebbe anche prendere in considerazione questo:

data Tag = A | B | C | D 
data Foo = X String Int | Tagged Tag String 

f (X s _) = s 
f (Tagged _ s) = s 

Answer 2

Oltre a @ di DanielWagner risposta, in alternativa è quella di utilizzare Scrap your boilerplate (AKA "SYB"). Ti permette di trovare il primo sottotipo di un determinato tipo. Così si potrebbe definire

{-# LANGUAGE DeriveDataTypeable #-} 

import Control.Monad 
import Data.Data 
import Data.Generics.Schemes 
import Data.Typeable 

data Foo = X (String, Int) | A String | B String | C String | D String 
    deriving (Show, Eq, Ord, Data, Typeable) 

fooString :: Foo -> Maybe String 
fooString = msum . gmapQ cast 

e fooString tornerà il primo String argomento dei tuoi costruttori. Funzione cast filtri fuori String se gmapQ ottiene i valori filtrati per tutti i sottotemi immediati.

Tuttavia, questo non restituirà il String da X, perché X non ha immediata String sottotermine, si ha un solo sottotermine di tipo (String, Int). Al fine di ottenere il primo String ovunque nella gerarchia termine, è possibile utilizzare everywhere:

fooString' :: Foo -> Maybe String 
fooString' = everything mplus cast 

Si noti che questo approccio è un po 'fragile: Comprende semplicemente tutto String s che trova, che potrebbe non essere sempre quello che si vuole , in particolare, se in seguito si estende il tipo di dati (o alcuni tipi di dati a cui fa riferimento).