Perché gli elenchi di differenze non sono un'istanza di pieghevole?

Question

Il dlist package contiene il tipo di dati DList, che ha molte istanze, ma non Foldable o Traversable. Nella mia mente, queste sono due delle classi di tipo più "classiche". C'è un motivo di prestazioni che DList non è un'istanza di queste classi?

Inoltre, il pacchetto implementa foldr e , ma nessuna delle altre funzioni di piegatura.

Answer 1

DList a è un involucro intorno newtype [a] -> [a], che ha un a in posizione controvariante, quindi non si può attuare Foldable o Traversable, o anche Functor direttamente. L'unico modo per implementarli è la conversione da e verso gli elenchi normali (vedere l'implementazione foldr), che sconfigge il vantaggio prestazionale degli elenchi di differenze.

Answer 2

Un'alternativa da considerare invece di DList consiste nell'utilizzare elenchi codificati di Church. L'idea è di rappresentare un elenco come un valore opaco che sa come eseguire uno foldr su un elenco. Ciò richiede l'utilizzo del RankNTypes estensione:

{-# LANGUAGE RankNTypes #-} 

import Prelude 
import Control.Applicative 
import Data.Foldable (Foldable) 
import qualified Data.Foldable as F 
import Data.Traversable (Traversable) 
import qualified Data.Traversable as T 

-- | Laws: 
-- 
-- > runList xs cons nil == xs 
-- > runList (fromList xs) f z == foldr f z xs 
-- > foldr f z (toList xs) == runList xs f z 
newtype ChurchList a = 
    ChurchList { runList :: forall r. (a -> r -> r) -> r -> r } 

-- | Make a 'ChurchList' out of a regular list. 
fromList :: [a] -> ChurchList a 
fromList xs = ChurchList $ \k z -> foldr k z xs 

-- | Turn a 'ChurchList' into a regular list. 
toList :: ChurchList a -> [a] 
toList xs = runList xs (:) [] 

-- | We can construct an empty 'ChurchList' without using a @[]@. 
nil :: ChurchList a 
nil = ChurchList $ \_ z -> z 

-- | The 'ChurchList' counterpart to '(:)'. Unlike 'DList', whose 
-- implementation uses the regular list type, 'ChurchList' doesn't 
-- rely on it at all. 
cons :: a -> ChurchList a -> ChurchList a 
cons x xs = ChurchList $ \k z -> k x (runList xs k z) 

-- | Append two 'ChurchList's. This runs in O(1) time. Note that 
-- there is no need to materialize the lists as @[a]@. 
append :: ChurchList a -> ChurchList a -> ChurchList a 
append xs ys = ChurchList $ \k z -> runList xs k (runList ys k z) 

-- | Map over a 'ChurchList'. No need to materialize the list. 
instance Functor ChurchList where 
    fmap f xs = ChurchList $ \k z -> runList xs (\x xs' -> k (f x) xs') z 

-- | The 'Foldable' instance is trivial, given the 'ChurchList' law. 
instance Foldable ChurchList where 
    foldr f z xs = runList xs f z 

instance Traversable ChurchList where 
    traverse f xs = runList xs step (pure nil) 
     where step x rest = cons <$> f x <*> rest 

Lo svantaggio di questo è che non c'è efficiente tail operazione per un ChurchList -il piegamento una ChurchList è economico, ma prendendo ripetuta code è costoso ...