richiedere una password in Haskell applicazione a riga di comando

Question

Il seguente programma Haskell richiede all'utente una password nel terminale e continua, se è entrato quello corretto:

main = do 
    putStrLn "Password:" 
    password <- getLine 

    case hash password `member` database of 
     False -> putStrLn "Unauthorized use!" 
     True -> do 
       ... 

Purtroppo, la password apparirà sul schermo come l'utente lo digita, che voglio evitare.

Come posso leggere una sequenza di caratteri che l'utente digita senza visualizzare sullo schermo? Qual è l'equivalente di getLine per questo scopo?

Sono su MacOS X, ma mi piacerebbe che funzionasse anche su Windows e Linux.

Answer 1

provare il prossimo:

module Main 
where 

import System.IO 
import Control.Exception 

main :: IO() 
main = getPassword >>= putStrLn . ("Entered: " ++) 

getPassword :: IO String 
getPassword = do 
    putStr "Password: " 
    hFlush stdout 
    pass <- withEcho False getLine 
    putChar '\n' 
    return pass 

withEcho :: Bool -> IO a -> IO a 
withEcho echo action = do 
    old <- hGetEcho stdin 
    bracket_ (hSetEcho stdin echo) (hSetEcho stdin old) action 

Answer 2

È possibile disattivare l'eco nel terminale con the System.Posix.Terminal module. Tuttavia, questo richiede il supporto POSIX, quindi potrebbe non funzionare su Windows (non ho controllato).

import System.Posix.Terminal 
import System.Posix.IO (stdInput) 

getPassword :: IO String 
getPassword = do 
    tc <- getTerminalAttributes stdInput 
    setTerminalAttributes stdInput (withoutMode tc EnableEcho) Immediately 
    password <- getLine 
    setTerminalAttributes stdInput tc Immediately 
    return password 

main = do 
    putStrLn "Password:" 
    password <- getPassword 
    putStrLn "Name:" 
    name <- getLine 
    putStrLn $ "Your password is " ++ password ++ " and your name is " ++ name 

noti che lo stdin è la linea tamponata, quindi se si utilizza putStr "Password:" invece di putStrLn, è necessario svuotare il buffer prima, altrimenti la richiesta sarà inibita.

Answer 3

C'è una getPassword in System.Console.Haskeline. Probabilmente è un eccesso per il tuo caso ma qualcuno potrebbe trovarlo utile.

Un esempio:

> runInputT defaultSettings $ do {p <- getPassword (Just '*') "pass:"; outputStrLn $ fromJust p} 
pass:*** 
asd 

Answer 4

Come ho già commentato in precedenza, ti suggerisco di usare haskeline, che è una libreria pronta pieno. L'ho usato felicemente per LambdaCalculator senza lamentele.

Answer 5

withEcho può essere scritto con un po 'meno rumore:

withEcho :: Bool -> IO a -> IO a 
withEcho echo action = 
    bracket (hGetEcho stdin) 
      (hSetEcho stdin) 
      (const $ hSetEcho stdin echo >> action)