Gnuplot e complessi esponenziali

Question

Qualcuno potrebbe dirmi come disegnare esponenziali complessi usando gnuplot. Ho provato a disegnarli usando questo script, ma l'argomento i non è riconosciuto.

set terminal epslatex color colortext size 9cm,5cm 
set size 1.5,1.0 
set output "eulerjeva_identiteta_1.tex" 

set style line 1 linetype 1 linewidth 3 linecolor rgb "#FF0055" 
set style line 2 linetype 2 linewidth 1 linecolor rgb "#FF0055" 
set style line 3 linetype 1 linewidth 3 linecolor rgb "#2C397D" 
set style line 4 linetype 2 linewidth 1 linecolor rgb "#2C397D" 
set style line 5 linetype 1 linewidth 3 linecolor rgb "#793715" 
set style line 6 linetype 2 linewidth 1 linecolor rgb "#793715" 
set style line 7 linetype 1 linewidth 3 linecolor rgb "#b1b1b1" 
set style line 8 linetype 3 linewidth 1 linecolor rgb "#b1b1b1" 

set grid 

set samples 7000 

set key at graph .95, 0.4 
set key samplen 2 
set key spacing 0.8 

f(x) = exp(i*x) 
g(x) = exp(-i*x) 
h(x) = exp(i*x)+exp(-i*x) 

set xrange [-2*pi:2*pi] 
set yrange [-1.2:1.2] 

set xtics ("$0$" 0, "$\\pi$" pi, "$-\\pi$" -pi) 
set ytics ("$1$" 1, "$-1$" -1) 

set xlabel "$x$" 

plot [-2*pi:2*pi] f(x) ls 1 title "$\\e^{ix}$", g(x) ls 3 title "$\\e^{-ix}$", h(x) ls 5 title "$\\e^{ix} + \\e^{-ix}$" 

Answer 1

Gnuplot non capisce come isqrt(-1) perché la variabile i non viene assegnato un valore da gnuplot - è solo un altro nome di variabile, per quanto lo riguarda. Gnuplot in grado di capire e manipolare i numeri complessi usando il formato

z = {a,b} 

che rappresenta un numero complesso z = (a + ib) in notazione scritta. Quindi, potrei essere definito

i = {0.0,1.0} 

C'è ancora il problema di quello che si ottiene quando si poi grafico

plot exp(i*x) 

Tutti i punti sono 'undefined' perché hanno una componente immaginaria. (Anche se, h(x) = exp(i*x)+exp(-i*x) potrebbe trame bene dato che è puramente reale.) Il problema è che gnuplot può tracciare solo quantità reali. Si potrebbe provare

plot real(exp(i*x)), imag(exp(i*x)) 

per visualizzare i componenti separatamente, o si potrebbe fare una trama parametrico:

set parametric 
plot real(exp(i*t)), imag(exp(i*t))