inserire l'intero recordset ADO nella tabella ACCESSO esistente WITHOUT LOOP

Question

Ho un recordset ADO pieno nel mio modulo VBA. Ho anche una tabella in ACCESS che ha esattamente la stessa struttura del recordset.

Ora riempio la tabella utilizzando un ciclo (che va bene) passando per ogni record del set di dati.

Quello che mi chiedo: c'è un modo per inserire un intero recordset nel tavolo degli accessi? (e ancora più importante: sarebbe molto più veloce)

Answer 1

Ecco un esempio di base (eseguito da Excel in questo caso) che illustra l'utilizzo di un recordset disconnesso per aggiungere record.

Sub Tester() 

    Dim con As ADODB.Connection, rs As ADODB.Recordset 
    Dim i As Long 

    Set con = getConn() 

    Set rs = New ADODB.Recordset 
    rs.CursorLocation = adUseClient '<<<< important! 

    'get an empty recordset to add new records to 
    rs.Open "select * from Table1 where false", con, _ 
      adOpenDynamic, adLockBatchOptimistic 

    'disconnect the recordset and close the connection 
    Set rs.ActiveConnection = Nothing 
    con.Close 
    Set con = Nothing 

    'add some new records to our test recordset 
    For i = 1 To 100 
     rs.AddNew 
     rs("UserName") = "Newuser_" & i 
    Next i 

    'reconnect to update 
    Set con = getConn() 
    Set rs.ActiveConnection = con 

    rs.UpdateBatch '<<< transfer to DB happens here: no loop! 

    rs.Close 

    'requery to demonstrate insert was successful 
    rs.Open "select * from Table1", con, _ 
      adOpenDynamic, adLockBatchOptimistic 

    Do While Not rs.EOF 
     Debug.Print rs("ID").Value, rs("UserName").Value 
     rs.MoveNext 
    Loop 

    rs.Close 
    con.Close 
End Sub 

Function getConn() As ADODB.Connection 
    Dim rv As New ADODB.Connection 
    Dim strConn As String 

    strConn = "Provider=Microsoft.ACE.OLEDB.12.0;" _ 
    & "Data Source = " & ThisWorkbook.Path & "\Test.accdb" 

    rv.Open strConn 
    Set getConn = rv 
End Function 

Answer 2

No. Non esiste un equivalente inverso - potrebbe essere SetRows - al metodo GetRows.

Answer 3

Recordsets VBA esistono praticamente in memoria chiamata durante l'esecuzione finché non sono contenuti in un formato fisico reale (cioè, csv, txt, xlsx, XML, temperatura tabella di database) salvato sul disco rigido. Questo è simile ai frame di dati in panda R o Python, dataset SAS, array PHP e altre strutture dati.

Considera l'esportazione dell'ADO in tale formato utilizzando i metodi CopyFromRecordset in un foglio di calcolo Excel da salvare come csv, txt, xlsx o xml. In alternativa, è possibile utilizzare il metodo Save per salvare il recordset in un tipo di formato persistente come xml.

Poi, aggiungere file risultante a tavola MS Access con le sue funzioni automatiche di migrazione dei dati:

• Per i fogli di calcolo: DoCmd.TransferSpreadsheet
• Per txt, csv, o altri file delimitati: DoCmd.TransferText
• per i file XML : Application.ImportXML
• Per/OLEDB legata tabelle di database locali o ODBC: INSERT INTO Query di accodamento SQL

---