Ottenere un elenco di tutte le finestre aperte utilizzando AutoIt

Question

Sto cercando di sbarazzarsi dei miei pulsanti minimizza, massimizza e chiudi su tutte le finestre. Googling in giro ho trovato questo:

$h = WinGetHandle("[CLASS:Notepad]") 

$iOldStyle = _WinAPI_GetWindowLong($h, $GWL_STYLE) 
$iNewStyle = BitXOr($iOldStyle, $WS_SYSMENU) 
_WinAPI_SetWindowLong($h, $GWL_STYLE, $iNewStyle) 
_WinAPI_ShowWindow($h, @SW_SHOW) 

Questo funziona bene, così ora ho solo bisogno di iterare su tutte le finestre con questo codice, e ho finito. Come posso ottenere un elenco di tutti gli HWNDs nel sistema?

Answer 1

È possibile ottenere un elenco di tutte le finestre aperte utilizzando WinList:

$aWindows = WinList() 
For $i=1 To $aWindows[0][0] 

    ; skip windows without a title 
    If $aWindows[$i][0] = '' Then ContinueLoop 

    ;use the HWND to get the state of the window 
    $iWndState = WinGetState($aWindows[$i][1]) 

    ; here you could filter out the windows you don't want to modify 
    ConsoleWrite($aWindows[$i][0] & ': ') 
    If BitAND($iWndState,1) = 1 Then ConsoleWrite(' exists') 
    If BitAND($iWndState,2) = 2 Then ConsoleWrite(' visible') 
    If BitAND($iWndState,4) = 4 Then ConsoleWrite(' enabled') 
    If BitAND($iWndState,8) = 8 Then ConsoleWrite(' active') 
    If BitAND($iWndState,16) = 16 Then ConsoleWrite(' minimised') 
    If BitAND($iWndState,32) = 32 Then ConsoleWrite(' maximised') 
    ConsoleWrite(@CRLF) 
Next