Come ottenere VBA Macro per eseguire continuamente in background?

Question

Voglio monitorare un valore e ricevere notifiche via email quando determinate condizioni sono soddisfatte. Ho una macro in questo modo:

Do While True 

    Worksheet.Calculate 

    If Value > 10 Then 
     SendEmail 
    End If 

    Sleep 60*CLng(1000) 

Loop 

Tuttavia, quando si esegue questo, intasa l'intero programma e si accende non risponde se cerco di fare qualsiasi cosa.

Esiste comunque lo scopo di farlo funzionare in background o almeno non arrestare il programma?

Quello che stavo facendo prima era usare VBScript per aprire un foglio di calcolo non visibile e VBScript funzionava continuamente in background, monitorando la condizione e funzionava bene, ma il mio cliente vuole davvero una GUI e che sia nel programma stesso .

Qualche idea?

Answer 1

Utilizzare il metodo Application.OnTime per pianificare il codice che verrà eseguito in un minuto.

Il codice sarà simile a questa (non testata):

Sub CreateNewSchedule() 
    Application.OnTime EarliestTime:=DateAdd("n", 1, Now), Procedure:="macro_name", Schedule:=True 
End Sub 

Sub macro_name() 

    If Value > 10 Then 
     SendEmail 
    Else 
     CreateNewSchedule 
    End If 

End Sub 

Si potrebbe desiderare di memorizzare l'ora del prossimo programma in una variabile globale in modo che l'evento Workbook_BeforeClose può annullare il programma successivo. In caso contrario, Excel riaprirà la cartella di lavoro.

Public nextScheduledTime As Date 

Sub CreateNewSchedule() 
    nextScheduledTime = DateAdd("n", 1, Now) 
    Application.OnTime EarliestTime:=nextScheduledTime , Procedure:="macro_name", Schedule:=True 
End Sub 

Sub macro_name() 

    If Value > 10 Then 
     SendEmail 
    Else 
     CreateNewSchedule 
    End If 

End Sub 

Private Sub Workbook_BeforeClose(Cancel As Boolean) 
On Error Resume Next 
    Application.OnTime EarliestTime:=nextScheduledTime, Procedure:="macro_name", Schedule:=False 
End Sub 

È quindi possibile continuare a utilizzare Excel tra gli orari pianificati.

Answer 2

Penso che sia necessario elaborare in modo specifico lo stack di eventi dell'applicazione con una chiamata DoEvents. Ciò consente alle interazioni dell'utente con il foglio di calcolo di verificarsi, dove normalmente la macro avrebbe la precedenza. È il codice sarebbe simile:

Do While True 

    If Value > 10 Then 
     SendEmail 
    End If 

    Sleep 60*CLng(1000) 

    DoEvents 
Loop 

Si potrebbe anche costruire una GUI con HTA se si voleva rimanere con VBScript.