Perl readdir nell'ordine

Question

Esiste un modo per garantire un ordine dall'elenco restituito da readdir?

Ho il codice:

opendir(my $DIR, $src) or die "Error opening $src"; 

# Loop for each file in the directory 
while (my $file = readdir($DIR)) 
{ 
     print "$file\n"; 
} 

ma restituisce in ordine casuale. Ora so che ci sono molte soluzioni tramite una rapida ricerca su Google, ma non riesco a trovare l'ordine esatto di cui ho bisogno .. Fondamentalmente voglio che le cartelle appaiano PRIMA o ULTIMA, e non tra i file.

Per esempio, in questo momento se ho la struttura di cartelle:

folder 
folder 
file1 
file2 
file3 

ottengo il risultato:

file2 
folder 
folder 
file1 
file3 

quando in realtà voglio:

folder 
folder 
file1 
file2 
file3 

Oppure:

file1 
file2 
file3 
folder 
folder 

Un modo per raggiungere questo obiettivo?

Grazie.

Answer 1

È possibile ordinare mettendo le cartelle prima e poi l'ordinamento per file/dir name,

# $src pointing to folder open with opendir 
my @sorted_dir = 
    map $_->[0], 
    sort { 
    $a->[1] <=> $b->[1] 
     || 
    $a->[0] cmp $b->[0] 
    } 
    map [ $_, -f "$src/$_" ], 
    readdir($DIR); 

Mentre effetto simile può essere ottenuto con,

for my $file (sort { -f "$src/$a" <=> -f "$src/$b" } readdir($DIR)) { 
    print "$file\n"; 
} 

è più lento e inefficiente, come più spesso va al file system controllando se la voce della directory è un file semplice.

Answer 2

È possibile utilizzare uno sort per farlo, esaminando ogni voce della lista restituita da readdir.

opendir(my $DIR, '.') or die "Error opening "; 

foreach my $file (sort { -d $a <=> -d $b } readdir($DIR)) { 
    print "$file\n"; 
} 

Questo darà le cartelle per ultime.

Answer 3

È possibile utilizzare part da List::MoreUtils

#!/usr/bin/env perl 

use strict; 
use warnings; 

use List::MoreUtils 'part'; 

my $dir = shift || '.'; 

opendir my $dh, $dir or die "Cannot open $dir"; 

my ($files, $dirs) = part { -d } sort readdir $dh; 

print "$_\n" for @$files, @$dirs; 

Per un'altra idea, si potrebbe guardare File::Next.

Answer 4

foreach (sort readdir $dh) {} funziona bene per me.

Ad esempio:

opendir (my $DIR, "$dir") || die "Error while opening $dir: $!\n"; 

foreach my $dirFileName(sort readdir $DIR) 
{ 
     next if $dirFileName eq '.' or $dirFileName eq '..'; 
     print("fileName: $dirFileName ... \n"); 
}