Batch Script per eliminare la cartella più vecchia in una data cartella

Question

Sto scrivendo un semplice script di backup .bat e, come parte di esso, voglio che il backup più vecchio (cartella) venga eliminato al raggiungimento di un limite massimo di backup.

In questo momento ho questo:

%COUNTER% si basa sul numero di cartelle di backup attualmente nella directory in cui sono memorizzati i backup, ed è calcolato in precedenza nello script.

%MAXBACKUPS% è solo un numero specificato dall'utente come "10", per indicare che si desidera conservare solo fino a 10 versioni dei backup.

:: Delete the oldest backup, but only if we've exceeded the desired number of backups. 
IF %COUNTER% gtr %MAXBACKUPS% (
ECHO More than %MAXBACKUPS% backups exist. Deleting oldest... 
FOR /f "delims=" %%a in ('dir "..\Backup\*" /t:c /a:d /o:-d /b') do rd /s /q "..\Backup\%%a" 
::Increment the counter down since we've just removed a backup folder. 
SET /a COUNTER=%COUNTER%-1 
) 

Vorrei che questo script per solo eliminare l'una cartella più antica nella cartella ..\Backup, ma così com'è sembra cancellare ogni singola cartella che trova una volta che raggiunge il limite di backup, che non è ovviamente il desiderato comportamento.

Answer 1

Eri così vicino! :-)

Tutto ciò che dovete fare è saltare le prime voci %MAXBACKUPS% quando ordinate per data decrescente. Non hai nemmeno bisogno della tua variabile COUNTER.

:: Preserve only the %MAXBACKUPS% most recent backups. 
set "delMsg=" 
for /f "skip=%MAXBACKUPS% delims=" %%a in (
    'dir "..\Backup\*" /t:c /a:d /o:-d /b' 
) do (
    if not defined delMsg (
    set delMsg=1 
    echo More than %MAXBACKUPS% found - only the %MAXBACKUPS% most recent folders will be preserved. 
) 
    rd /s /q "..\Backup\%%a" 
) 

Answer 2

FOR /f "delims=" %%a in ('dir "..\Backup\*" /t:c /a:d /o:d /b') do (
rd /s /q "..\Backup\%%a" 
goto :break 
) 
:break 

si può rompere il ciclo con goto

Answer 3

Un modo semplice per fare questo, sulla base di script:

FOR /f "delims=" %%a in ('dir "..\Backup\*" /t:c /a:d /o:-d /b') do set lastfolder=%%a 

rd /s /q "..\Backup\%lastfolder%" 

quindi è ancora un ciclo su ogni cartella, in ordine di età, ma si sovrascrive% lastfolder% quindi alla fine contiene solo il nome della cartella meno recente.

Quindi si elimina quella cartella.

Answer 4

Ecco l'ultimo blocco di codice ho finito per usare:

:: Preserve only the %MAXBACKUPS% most recent backups. 
FOR /f "skip=%MAXBACKUPS% delims=" %%a in (
'dir "..\Backup\*" /t:c /a:d /o:-d /b' 
) do (
ECHO More than %MAXBACKUPS% backups found--Deleting "%%a". 
ECHO. 
rd /s /q "..\Backup\%%a" 
) 

semplifica il codice di eliminazione di messaggio un po ', e fornisce all'utente finale con le informazioni su ciò che il file è stato eliminato nel prompt dei comandi finestra.

Sulla base dbenham's answer.