VBA Outlook chiama Excel Macro e aspetta che la macro sia stata completata

Question

Sto chiamando una macro di Excel da uno script di regole di Outlook.

Il processo è: Ottenere la posta, eseguire una regola di Outlook che esegue uno script di Outlook, aprire Excel da quello script, eseguire la macro di Excel, chiudere Excel.

Come posso verificare nello script di regole di Outlook che la macro di Excel è stata eseguita, per salvare e chiudere l'applicazione?

Sub AskMeAlerts() 
Dim appExcel As Excel.Application 
Dim wkb As Excel.Workbook 
Set appExcel = CreateObject("Excel.Application") 
appExcel.Workbooks.Open ("C:\Ask me question workflow.xlsm") 
appExcel.Visible = True 
appExcel.Run "'Ask me question workflow.xlsm'!AskMeFlow" 
appExcel.DisplayAlerts = False 
appExcel.ActiveWorkbook.Save 
appExcel.Quit Set appExcel = Nothing 
Set wkb = Nothing 
End Sub 

Answer 1

Si potrebbe o

1. Port macro di Excel in Outlook ed eseguirlo direttamente
2. Utilizzare un bandiera per catturare il completamento del codice

Il seguente codice utilizza un marcatore in A1 del primo foglio per catturare il codice da eseguire (nella parte di Excel). Ho anche venivano pulite il codice (era un mix di precoce e un successivo binding)

codice prospettive

Sub AskMeAlerts() 
Dim appExcel As Excel.Application 
Set appExcel = New Excel.Application 
With appExcel 
    .DisplayAlerts = False 
    .Workbooks.Open ("C:\TEMP\Ask me question workflow.xlsm") 
    .Run "'Ask me question workflow.xlsm'!AskMeFlow" 
    If .activeworkbook.sheets(1).[a1].Value = "Complete" Then 
     MsgBox "Code has run" 
     .activeworkbook.sheets(1).[a1].Value = vbNullString 
     .activeworkbook.Save 
     .DisplayAlerts = True 
     .activeworkbook.Close 
     appExcel.Quit 
     Set appExcel = Nothing 
    End If 
End With 
End Sub 

eccellono codice

Sub AskMeFloW() 
'do stuff 
ThisWorkbook.Sheets(1).[a1] = "Complete" 
End Sub 

Answer 2

Un modo molto semplice, è di implementare una serratura.

Questo codice è una soluzione rapida e sporca, verificando l'esistenza di un file, in un luogo predefinito.

in C:\Ask me question workflow.xlsm aggiungere questo sub:

Sub WrapAskMeFlow() 
    Dim tmpFile As String 
    tmpFile = "C:\AskMeFlow.tmp" 
    Open tmpFile for Output as #1 
    Close #1 
    AskMeFlow 
    Kill tmpFile 
End Sub 

in Outlook macro aggiuntivo:

Sub AskMeAlerts() 
Dim appExcel As Excel.Application 
Dim wkb As Excel.Workbook 
Set appExcel = CreateObject("Excel.Application") 
appExcel.Workbooks.Open ("C:\Ask me question workflow.xlsm") 
appExcel.Visible = True 
appExcel.Run "'Ask me question workflow.xlsm'!WrapAskMeFlow" 
appExcel.DisplayAlerts = False 
While Dir("C:\AskMeFlow.tmp")="":DoEvents:Wend 
While Dir("C:\AskMeFlow.tmp")<>"":DoEvents:Wend 
appExcel.ActiveWorkbook.Save 
appExcel.Quit Set appExcel = Nothing 
Set wkb = Nothing 
End Sub 

Answer 3

Opzione 1

L'opzione più semplice nel tuo caso specifico sarebbe quello di costruire il salva e chiudi i comandi nella macro di Excel anziché in quella di Outlook.

Che è, si potrebbe modificare il codice di Outlook per:

Sub AskMeAlerts() 
Dim appExcel As Excel.Application 
Dim wkb As Excel.Workbook 'Is this declaration necessary for some code elsewhere? You do not use this variable and I would recommend removing the declaration. 
     Set appExcel = CreateObject("Excel.Application") 
     With appExcel 
      .Workbooks.Open ("C:\Ask me question workflow.xlsm") 
      .Visible = True 
      .Run "'Ask me question workflow.xlsm'!AskMeFlow" 
     'No need to explicitly set alert values or save workbook as Excel macro will handle this. 
     End With 
     Set appExcel = Nothing 
     Set wkb = Nothing 'Again, is this necessary? 
End Sub 

Si potrebbe quindi aggiungere il seguente alla fine del "Chiedimi discussione workflow.xlsm" file:

Application.DisplayAlerts = False 
ThisWorkbook.Close SaveChanges:=True 
Application.Quit 

Nota: se esegui la macro manualmente o in altri casi d'uso in cui non vuoi che la cartella di lavoro salvi, chiudi e chiudi, potresti considerare l'aggiunta di una variabile di input alla macro AskMeFlow che è impostata su False ma è impostata su Vero da Outlook. Penso che questo sia leggermente al di fuori della portata di questa risposta, quindi non approfondirò ulteriormente, ma fammi sapere se sei interessato a questa opzione.

Opzione 2

Redacted. Vedi la soluzione di Uri; i miglioramenti che ho suggerito non modificano sostanzialmente questa soluzione.

Opzione 3

A seconda della natura del codice di Excel, si potrebbe trasformare in una funzione e catturare la variabile di uscita. Qualcosa come il qui sotto:

Sub AskMeAlerts() 
Dim appExcel As Excel.Application 
Dim wkb As Excel.Workbook 
Dim StrOutput as string 
StrOutput = "Excel macro did not complete." 
Set appExcel = CreateObject("Excel.Application") 
appExcel.Workbooks.Open ("C:\Ask me question workflow.xlsm") 
appExcel.Visible = True 
StrOutput = appExcel.Run "'Ask me question workflow.xlsm'!AskMeFlow" 
MsgBox StrOutput 
appExcel.DisplayAlerts = False 
appExcel.ActiveWorkbook.Save 
appExcel.Quit Set appExcel = Nothing 
Set wkb = Nothing 
End Sub 

Si potrebbe quindi cambiare AskMeFlow a una funzione e aggiungere il seguente codice:

Function AskMeFlow() as String 
AskMeFlow = "Uncaught error executing Excel code." 
'Your code here 
AskMeFlow = "Excel code completed successfully!" 
End Function 

Answer 4

Se Sub AskMeFlow fare calcoli senza l'intervento dell'utente, suppongo che si può semplicemente tenere traccia di Excel di CalculationState .

Sub AskMeAlerts() 
    With CreateObject("Excel.Application") 
     .Workbooks.Open ("C:\Ask me question workflow.xlsm") 
     .Visible = True 

     ' Ensure Autocalculation is on 
     .Calculation = -4105 ' xlCalculationAutomatic 

     .DisplayAlerts = False 
     .Run "'Ask me question workflow.xlsm'!AskMeFlow" 

     ' Wait until calculation is done 
     Do Until .CalculationState = 0 ' xlDone 
      DoEvents 
     Loop 

     .ActiveWorkbook.Save 
     .ActiveWorkbook.Close 
     .Quit 
    End With 
End Sub 

Sarebbe ancora meglio se il AskMeFlow è AUTO eseguito in Workbook_Open evento (all'interno di "ThisWorkbook" modulo).

Answer 5

La macro di Excel dovrebbe terminare chiudendo tutte le cartelle di lavoro, e Outlook aspetterebbe finché ci sono ancora cartelle di lavoro aperte.

In Excel:

// do work 
Application.ActiveWorkbook.Save 
Application.DisplayAlerts = False 
For Each wrkbk In Application.Workbooks 
    If wrkbk.Name <> ThisWorkbook.Name Then wrkbk.Close 
Next 
ThisWorkbook.Save 
ThisWorkbook.Close 

La macro di Outlook può piscina fino Workbooks.Count = a zero

While appExcel.Workbooks.Count > 0 :DoEvents:Wend 
appExcel.DisplayAlerts = False 
appExcel.Quit 
Set appExcel = Nothing 

Answer 6

Terminare il codice con il seguente:

On Error Resume Next 
    On Error GoTo 0 

ExitFunction: 
    Set objShell = Nothing 

End Function