Il modo più semplice per popolare una tabella temporanea con date comprese tra 2 parametri di data

Question

Qual è il modo più semplice per compilare una tabella temporanea con date incluse e tra 2 parametri di data. Ho solo bisogno delle date del primo giorno del mese.

Così, per esempio, se @StartDate = '2011-01-01' e @EndDate = '2011-08-01'

poi voglio questa tornato nella tabella

2011-01-01 
2011-02-01 
2011-03-01 
2011-04-01 
2011-05-01 
2011-06-01 
2011-07-01 
2011-08-01 

Answer 1

questo funziona anche se il @StartDate non è il primo del mese. Suppongo che se non è l'inizio del mese, vuoi iniziare con il primo del prossimo mese. In caso contrario, rimuovere il +1 .:

;WITH cte AS (
SELECT CASE WHEN DATEPART(Day,@StartDate) = 1 THEN @StartDate 
      ELSE DATEADD(Month,DATEDIFF(Month,0,@StartDate)+1,0) END AS myDate 
UNION ALL 
SELECT DATEADD(Month,1,myDate) 
FROM cte 
WHERE DATEADD(Month,1,myDate) <= @EndDate 
) 
SELECT myDate 
FROM cte 
OPTION (MAXRECURSION 0) 

Answer 2

declare @StartDate datetime 
declare @EndDate datetime 
select @StartDate = '2011-01-01' , @EndDate = '2011-08-01' 

select @StartDate= @StartDate-(DATEPART(DD,@StartDate)-1) 

declare @temp table 
(
TheDate datetime 
) 
while (@StartDate<=@EndDate) 
begin 
insert into @temp 
values (@StartDate) 
select @StartDate=DATEADD(MM,1,@StartDate) 
end 
select * from @temp 

funziona anche se il @StartDate non è il primo giorno del mese andando indietro al giorno iniziale del mese di StartDate

Answer 3

Soluzione:

DECLARE @StartDate DATETIME 
     ,@EndDate DATETIME; 

SELECT @StartDate = '20110105' 
     ,@EndDate = '20110815'; 

SELECT DATEADD(MONTH, DATEDIFF(MONTH, 0, DATEADD(MONTH, v.number, @StartDate)), 0) AS FirstDay 
--or Andriy M suggestion: 
--SELECT DATEADD(MONTH, DATEDIFF(MONTH, 0, @StartDate) + v.number, 0) AS FirstDay 
INTO #Results 
FROM master.dbo.spt_values v 
WHERE v.type = 'P'   
AND  DATEDIFF(MONTH, @StartDate, @EndDate) >= v.number; 

SELECT * 
FROM #Results; 

DROP TABLE #Results; 

Risultati:

FirstDay 
----------------------- 
2011-01-01 00:00:00.000 
2011-02-01 00:00:00.000 
2011-03-01 00:00:00.000 
2011-04-01 00:00:00.000 
2011-05-01 00:00:00.000 
2011-06-01 00:00:00.000 
2011-07-01 00:00:00.000 
2011-08-01 00:00:00.000 

Answer 4

declare @StartDate date = '2014-01-01'; 
declare @EndDate date = '2014-05-05'; 

;WITH cte AS (
    SELECT @StartDate AS myDate 
    UNION ALL 
    SELECT DATEADD(day,1,myDate) as myDate 
    FROM cte 
    WHERE DATEADD(day,1,myDate) <= @EndDate 
) 
SELECT myDate 
FROM cte 
OPTION (MAXRECURSION 0) 

Answer 5

questo viene testato in SQL 2008 R2

Declare @StartDate datetime = '2015-03-01' 
Declare @EndDate datetime = '2015-03-31' 
declare @temp Table 
(
DayDate datetime 
); 

WHILE @StartDate <= @EndDate 
begin 
INSERT INTO @temp (DayDate) VALUES (@StartDate); 
SET @StartDate = Dateadd(Day,1, @StartDate); 
end ; 

select * from @temp 

Risultato:

DayDate 
----------------------- 
2015-03-01 00:00:00.000 
2015-03-02 00:00:00.000 
2015-03-03 00:00:00.000 
2015-03-04 00:00:00.000 
... 

Answer 6

È interessante notare, è più veloce di creare dai dati enumerati come da this article.

DECLARE @StartDate DATE = '10001201'; 
DECLARE @EndDate DATE = '20000101'; 

DECLARE @dim TABLE ([date] DATE) 

INSERT @dim([date]) 
SELECT d 
FROM 
(
    SELECT 
     d = DATEADD(DAY, rn - 1, @StartDate) 
    FROM 
    (
     SELECT TOP (DATEDIFF(DAY, @StartDate, @EndDate)) 
      rn = ROW_NUMBER() OVER (ORDER BY s1.[object_id]) 
     FROM 
      sys.all_objects AS s1 
     CROSS JOIN 
      sys.all_objects AS s2 
     ORDER BY 
      s1.[object_id] 
) AS x 
) AS y; 

Sulla mia macchina, è circa il 60% più veloce con grandi intervalli di date. Il metodo di ricorsione può riempire i dati di 2000 anni di dati in circa 3 secondi e sembra molto più bello, quindi non raccomando questo metodo solo per giorni di incremento.

Answer 7

di correzione per le date nulli:

IF OBJECT_ID('tempdb..#dim') IS NOT NULL 

    DROP TABLE #dim 

CREATE TABLE #dim ([date] DATE) 

if not @Begin_Date is null and not @End_Date is null 

begin 
    INSERT #dim([date]) 
    SELECT d 
    FROM(

     SELECT 
      d = DATEADD(DAY, rn - 1, @Begin_Date) 
     FROM 
     (
      SELECT TOP (DATEDIFF(DAY, @Begin_Date, @End_Date)) 
       rn = ROW_NUMBER() OVER (ORDER BY s1.[object_id]) 
      FROM 
       sys.all_objects AS s1 
      CROSS JOIN 
       sys.all_objects AS s2 
      ORDER BY 
       s1.[object_id] 
    ) AS x 
    ) AS y; 
end