VBA trova l'ultima occorrenza di una stringa

Question

Ho cercato di risolvere questo problema per alcuni giorni e non riesco a capirlo. Ho cercato più siti Web (anche qui più volte), ho visto che molte persone hanno fatto questa domanda ma le soluzioni non funzionano per me.

Voglio trovare l'ultima occorrenza di una stringa in un intervallo e memorizzare l'indirizzo in una variabile e visualizzare un messaggio che mi indica dove si trova.

Finora ho questo

Private Sub CmdBtnClockIt_Click() 
    Dim job As String 
    Dim searchTerm as Range 

    job = CmbBoxJob.Value 
    searchTerm = Range("A1:A999").find(what:=job, searchorder:=xlByColumns, searchdirection:=xlPrevious).Column 
    MsgBox "last cell is " & searchTerm.Address 
End Sub 

Tutti mi sembra di ottenere è uno "qualificatore non valido" o "oggetto variabile o con la variabile di blocco non impostata"

Ogni aiuto è apprezzato

Answer 1

Il primo problema è che searchTerm è definito come un oggetto Range. È necessario impostare le assegnazioni di oggetto utilizzando lo Set keyword. Così l'assegnazione diventa Set searchTerm = Range("A1:A999")...

In secondo luogo, vi ha colpito messaggi di errore se il searchTerm non viene trovato, perché searchTerm sarà assegnato un valore di Nothing. Possiamo evitare questo problema utilizzando una semplice condizione per verificare se è stato trovato il job.

Quindi la vostra aggiornato Sub potrebbe essere simile a questa:

Private Sub CmdBtnClockIt_Click() 
    Dim job As String 
    Dim searchTerm As Range 

    job = CmbBoxJob.Value 
    Set searchTerm = Range("A1:A999").Find(what:=job, searchorder:=xlByColumns, searchdirection:=xlPrevious) 
    If searchTerm Is Nothing Then 
    MsgBox "Text was not found" 
    Else 
    MsgBox "Last cell is " & searchTerm.Address 
    End If 
End Sub 

Answer 2

Che ne dite:

Sub dural() 
    Dim job As String 
    Dim searchTerm As Range 
    job = "Happiness" 
    Set searchTerm = Range("A1:A999").Find(what:=job, after:=Range("A1"), searchorder:=xlByColumns, searchdirection:=xlPrevious) 
    MsgBox "last cell is " & searchTerm.Address 
End Sub 

Avviso Ho utilizzato Set.