Crea una colonna e inseriscila all'interno della stessa transazione?

Question

È possibile creare una colonna e inserire valori durante la stessa transazione? Questo fa parte di uno script di aggiornamento. Ho trovato il seguente metodo online, ma non funziona; Viene visualizzato un messaggio di errore: Invalid column name 'IndexNumber'.. Suppongo che ciò sia dovuto al fatto che la transazione non ha ancora creato la colonna, quindi non c'è nulla da inserire.

Le parti rilevanti del mio script:

Print 'Beginning Upgrade' 
Begin Transaction 
    -- -------------------------------------------------------------------- 
    USE [MyDatabase]; 

    /* Widgets now can be ordered and the order can be modified */ 
    ALTER TABLE [dbo].[Widgets] ADD [IndexNumber] [int] NULL; 

    DECLARE @ind INT 
    SET @ind = 0 
    UPDATE [dbo].[Widgets] 
    SET @ind = [IndexNumber] = @ind + 1; 

    ALTER TABLE [dbo].[Widgets] ALTER COLUMN [IndexNumber] [int] NOT NULL; 
    -- -------------------------------------------------------------------- 
Commit tran 
Print 'Upgrade completed' 

Il motivo per cui [IndexNumber] non è una colonna di identità è che deve essere modificabile.

Answer 1

Un'altra alternativa, se non si desidera dividere il codice in lotti separati, è quello di utilizzare EXEC per creare uno scope/batch nidificati:

Print 'Beginning Upgrade' 
Begin Transaction 
    -- -------------------------------------------------------------------- 
    USE [MyDatabase]; 

    /* Widgets now can be ordered and the order can be modified */ 
    ALTER TABLE [dbo].[Widgets] ADD [IndexNumber] [int] NULL; 

    EXEC('DECLARE @ind INT 
    SET @ind = 0 
    UPDATE [dbo].[Widgets] 
    SET @ind = [IndexNumber] = @ind + 1;'); 

    ALTER TABLE [dbo].[Widgets] ALTER COLUMN [IndexNumber] [int] NOT NULL; 
    -- -------------------------------------------------------------------- 
Commit tran 
Print 'Upgrade completed' 

Il motivo per cui il codice originale non funziona b perché prova a compilare l'intero batch prima di eseguirlo - la compilazione fallisce e quindi non inizia nemmeno la transazione, lascia che altera la tabella.

Answer 2

Non è possibile aggiungere una nuova colonna e utilizzarla all'interno dello stesso lotto. È necessario inserire GO tra l'aggiunta di una colonna e l'utilizzo.

La transazione è ancora in ordine (è possibile testare modificando Commit tran a rollback tran per vedere che non sono state apportate modifiche).

Print 'Beginning Upgrade' 
Begin Transaction 
    -- -------------------------------------------------------------------- 
    USE [MyDatabase]; 

    /* Widgets now can be ordered and the order can be modified */ 
    ALTER TABLE [dbo].[Widgets] ADD [IndexNumber] [int] NULL; 

    GO 

    DECLARE @ind INT 
    SET @ind = 0 
    UPDATE [dbo].[Widgets] 
    SET @ind = [IndexNumber] = @ind + 1; 

    ALTER TABLE [dbo].[Widgets] ALTER COLUMN [IndexNumber] [int] NOT NULL; 
    -- -------------------------------------------------------------------- 
Commit tran 
Print 'Upgrade completed' 

Answer 3

chiamata 'go' dopo ALTER TABLE

USE [MyDatabase]; 

/* Widgets now can be ordered and the order can be modified */ 
ALTER TABLE [dbo].[Widgets] ADD [IndexNumber] [int] NULL; 
go 

DECLARE @ind INT 
SET @ind = 0 
UPDATE [dbo].[Widgets] 
SET @ind = [IndexNumber] = @ind + 1; 

ALTER TABLE [dbo].[Widgets] ALTER COLUMN [IndexNumber] [int] NOT NULL; 
-- -------------------------------------------------------------------- 

commit tran