Come rinominare il file sostituendo sottostringa utilizzando lotti in Windows

Question

voglio rinominare il nome del file come "how-to rinominare -file.jpg"-"how-to riutilizzo -file.jpg " utilizzando un file batch di Windows

Ie Voglio solo sostituire una o due parole in un nome di file.

Answer 1

@echo off 

Set "Filename=how-to-rename-file.jpg" 
Set "Pattern=rename" 
Set "Replace=reuse" 

REM Call Rename "%Filename%" "%%Filename:%Pattern%=%Replace%%%" 

Call Echo %%Filename:%Pattern%=%Replace%%% 
:: Result: how-to-reuse-file.jpg 

Pause&Exit 

Vi do altro esempio per un ciclo di file:

UPDATE:

ho perso alcune cose per la causa della sintassi' veloce di battitura mia ultima modifica, ecco il codice corretto:

@echo off 
Setlocal enabledelayedexpansion 

Set "Pattern=rename" 
Set "Replace=reuse" 

For %%# in ("C:\Folder\*.jpg") Do (
    Set "File=%%~nx#" 
    Ren "%%#" "!File:%Pattern%=%Replace%!" 
) 

Pause&Exit 

PS: leggi qui sotto per saperne di più sulla sottostringa: http://ss64.com/nt/syntax-substring.html http://ss64.com/nt/syntax-replace.html

Answer 2

Il codice di cui sopra non rinominare i file - I percorsi sono un problema e il nome del file di origine non è corretta.

Questo funzionerà sui file nella cartella corrente, ad eccezione di quelli con! nei nomi sarà un problema.

@echo off 
Setlocal enabledelayedexpansion 

Set "Pattern=rename" 
Set "Replace=reuse" 

For %%a in (*.jpg) Do (
    Set "File=%%~a" 
    Ren "%%a" "!File:%Pattern%=%Replace%!" 
) 

Pause&Exit