Problema con FileExists e Data di modifica

Question

Sul mio server ci sono alcuni file con Data di modifica 31/DEC/1979 (Non chiedermi il motivo). Quindi FileExists restituisce false.

Sysutils.FileExists assomiglia a questo:

function FileAge(const FileName: string): Integer; 
var 
    Handle: THandle; 
    FindData: TWin32FindData; 
    LocalFileTime: TFileTime; 
begin 
    Handle := FindFirstFile(PChar(FileName), FindData); 
    if Handle <> INVALID_HANDLE_VALUE then 
    begin 
    Windows.FindClose(Handle); 
    if (FindData.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY) = 0 then 
    begin 
     FileTimeToLocalFileTime(FindData.ftLastWriteTime, LocalFileTime); 
     if FileTimeToDosDateTime(LocalFileTime, LongRec(Result).Hi, 
     LongRec(Result).Lo) then Exit; 
    end; 
    end; 
    Result := -1; 
end; 

function FileExists(const FileName: string): Boolean; 
begin 
    Result := FileAge(FileName) <> -1; 
end; 

La mia domanda è, perché la funzione dipende FileAge in primo luogo? Non è la seguente riga sufficiente ?:

if (FindData.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY) = 0 then 
    // Yes the file exists! 

O anche sulla base di attributi di file:

function MyFileExists(const Name: string): Boolean; 
var 
    R: DWORD; 
begin 
    R := GetFileAttributes(PChar(Name)); 
    Result := (R <> DWORD(-1)) and ((R and FILE_ATTRIBUTE_DIRECTORY) = 0); 
end; 

Answer 1

Le versioni moderne di Delphi implementano FileExists in linea di massima allo stesso modo come il codice fa. L'implementazione ha una gestione extra per i collegamenti simbolici, ma è sostanzialmente identica alla tua versione.

C'è una sfumatura interessante nella moderna implementazione di Delphi. Se la chiamata a GetFileAttributes restituisce INVALID_FILE_ATTRIBUTES, il codice non viene immediatamente salvato. Invece lo fa:

LastError := GetLastError; 
Result := (LastError <> ERROR_FILE_NOT_FOUND) and 
    (LastError <> ERROR_PATH_NOT_FOUND) and 
    (LastError <> ERROR_INVALID_NAME) and ExistsLockedOrShared(Filename); 

E l'attuazione di ExistsLockedOrShared utilizza FindFirstFile e un assegno del FILE_ATTRIBUTE_DIRECTORY su dwFileAttributes. Ciò indica che GetFileAttributes può avere esito negativo quando il file esiste, ma è bloccato. Ma quello FindFirstFile può riuscire in tale scenario. Questo è ragionevole perché FindFirstFile utilizza i metadati del file anziché i dati memorizzati nel file stesso.

È difficile dire perché il codice sia così come è nelle versioni precedenti. Penso che sia debole. Personalmente sostituirò FileExists con una versione migliore, usando un hook di codice. Per esempio: Patch routine call in delphi

Come sempre, c'è un articolo Raymond Chen sul tema: Superstition: Why is GetFileAttributes the way old-timers test file existence?

Answer 2

A giudicare dalla realizzazione 'moderna' di FileExists (che non fa uso FileAge e anche ottimizzato e in grado di seguire i collegamenti simbolici per verificare se collegata esistono file):

• la prima variante ((FindData.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY) = 0) è OK;
• la seconda variante (GetFileAttributes) potrebbe non riuscire se il file è bloccato o condiviso.

Answer 3

Per il vecchio versios di Delphi è possibile scaricare la libreria di codici Jedi. Ha la seguente implementazione (oltre a molte altre classi e funzioni utili):

function FileExists(const FileName: string): Boolean; 
{$IFDEF MSWINDOWS} 
var 
    Attr: Cardinal; 
{$ENDIF MSWINDOWS} 
begin 
    if FileName <> '' then 
    begin 
    {$IFDEF MSWINDOWS} 
    // FileGetSize is very slow, GetFileAttributes is much faster 
    Attr := GetFileAttributes(Pointer(Filename)); 
    Result := (Attr <> $FFFFFFFF) and (Attr and FILE_ATTRIBUTE_DIRECTORY = 0); 
    {$ELSE ~MSWINDOWS} 
    // Attempt to access the file, doesn't matter how, using FileGetSize is as good as anything else. 
    Result := FileGetSize(FileName) <> -1; 
    {$ENDIF ~MSWINDOWS} 
    end 
    else 
    Result := False; 
end;