Tornando duplicati in una sequenza

Question

il meglio che potevo venire con era:

(defn dups [seq] 
    (map (fn [[id freq]] id) 
     (filter (fn [[id freq]] (> freq 1)) 
       (frequencies seq)))) 

Esiste un modo più conciso?

Answer 1

utilizzare un elenco di comprensione:

(defn dups [seq] 
    (for [[id freq] (frequencies seq) ;; get the frequencies, destructure 
     :when (> freq 1)]   ;; this is the filter condition 
    id))        ;; just need the id, not the frequency 

Answer 2

(map key (remove (comp #{1} val) 
       (frequencies seq))) 

Answer 3

Se vuoi per trovare i duplicati in base al largo alcune proprietà degli elementi della lista (cioè si tratta di un elenco di mappe o di un elenco di record/oggetti Java)

(defn dups-with-function 
    [seq f] 
    (->> seq 
     (group-by f) 
     ; filter out map entries where its value has only 1 item 
     (remove #(= 1 (count (val %)))))) 

(let [seq [{:attribute :one 
      :other-things :bob} 
      {:attribute :one 
      :other-things :smith} 
      {:attribute :two 
      :other-things :blah}]] 
    (dups-with-function seq :attribute)) 

uscite:

([:one 
    [{:attribute :one, :other-things :bob} 
    {:attribute :one, :other-things :smith}]]) 

Se si dispone di un elenco di oggetti Java e si desidera trovare tutte quelle con duplicati nomi:

(dups-with-function my-list #(.getFirstName %)) 

Answer 4

filtro Minimal e frequenze oneliner che fa il lavoro:

(filter #(< 1 ((frequencies col) %)) col) 

Tuttavia esegue scarsamente su grandi dati. Dovrai aiutare il compilatore dicendo:

(let [ freqs (frequencies col) ] 
    (filter #(< 1 (freqs %)) col))