Script batch per trovare e sostituire una stringa in un file di testo in un minuto per file fino a 12 MB

Question

Ho scritto uno script batch per sostituire una stringa nel file di testo.

Di seguito è riportata la sceneggiatura.

@echo off &setlocal 
set "search=%1" 
set "replace=%2" 
set "textfile=Input.txt" 
set "newfile=Output.txt" 
(for /f "delims=" %%i in (%textfile%) do (
    set "line=%%i" 
    setlocal enabledelayedexpansion 
    set "line=!line:%search%=%replace%!" 
    echo(!line! 
    endlocal 
))>"%newfile%" 
del %textfile% 
rename %newfile% %textfile% 

Ma per un file da 12 MB, ci vogliono quasi 7 minuti. Voglio che sia sotto un minuto. Possiamo utilizzare il comando find o findstr per ridurre il tempo impiegato?

Answer 1

Dare a questo un colpo:

@echo off 
setlocal 

call :FindReplace "findstr" "replacestr" input.txt 

exit /b 

:FindReplace <findstr> <replstr> <file> 
set tmp="%temp%\tmp.txt" 
If not exist %temp%\_.vbs call :MakeReplace 
for /f "tokens=*" %%a in ('dir "%3" /s /b /a-d /on') do (
    for /f "usebackq" %%b in (`Findstr /mic:"%~1" "%%a"`) do (
    echo(&Echo Replacing "%~1" with "%~2" in file %%~nxa 
    <%%a cscript //nologo %temp%\_.vbs "%~1" "%~2">%tmp% 
    if exist %tmp% move /Y %tmp% "%%~dpnxa">nul 
) 
) 
del %temp%\_.vbs 
exit /b 

:MakeReplace 
>%temp%\_.vbs echo with Wscript 
>>%temp%\_.vbs echo set args=.arguments 
>>%temp%\_.vbs echo .StdOut.Write _ 
>>%temp%\_.vbs echo Replace(.StdIn.ReadAll,args(0),args(1),1,-1,1) 
>>%temp%\_.vbs echo end with 

Answer 2

Una variante utilizzando Bat/PowerShell (bisogno .net framework):

replace.bat:

@echo off 

call:DoReplace "Findstr" "replacestr" test.txt test1.txt 
exit /b 

:DoReplace 
echo ^(Get-Content "%3"^) ^| ForEach-Object { $_ -replace %1, %2 } ^| Set-Content %4>Rep.ps1 
Powershell.exe -executionpolicy ByPass -File Rep.ps1 
if exist Rep.ps1 del Rep.ps1 
echo Done 
pause 

Answer 3

Questo utilizza un file batch di aiuto chiamato repl.bat - download da: https://www.dropbox.com/s/qidqwztmetbvklt/repl.bat

luogo repl.bat nella stessa cartella del file batch o in una cartella sul percorso.

Repl.bat è un file batch ibrido che utilizza script nativi di Windows ed è molto più veloce di uno script batch regolare.

L'opzione L effettua la ricerca del testo e sostituisce una stringa letterale e mi aspetto che il file da 12 MB venga completato in diversi secondi su un PC moderno.

@echo off &setlocal 
set "search=%~1" 
set "replace=%~2" 
set "textfile=Input.txt" 
set "newfile=Output.txt" 
call repl.bat "%search%" "%replace%" L < "%textfile%" >"%newfile%" 
del "%textfile%" 
rename "%newfile%" "%textfile%" 

Answer 4

Che ne dici, gente?

set search=%1 
set replace=%2 
set textfile=Input.txt  

set line1=with open('%textfile%', 'rw') as f: 
set line2=f.write(f.read().replace('%search%', '%replace%')) 
python -c "%line1%%line2%" 

Muhahaha

---

Edit:

In un folle oneliner

python -c "with open('%textfile%', 'rw') as f: f.write(f.read().replace('%search%', '%replace%'))" 

Answer 5

Prova questo:

@echo off &setlocal 
setlocal enabledelayedexpansion 

set "search=%1" 
set "replace=%2" 
set "textfile=Input.txt" 
set "newfile=Output.txt" 
(for /f "delims=" %%i in (%textfile%) do (
    set "line=%%i" 
    set "line=!line:%search%=%replace%!" 
    echo(!line! 
))>"%newfile%" 
del %textfile% 
rename %newfile% %textfile% 
endlocal 

Answer 6

Basta scaricare scoreggia (trovare e sostituire testo) da here

usarla in CMD (per facilità d'uso aggiungo cartella scoreggia alla mia variabile PATH)

Ecco un esempio:

fart -r "C:\myfolder\*.*" findSTR replaceSTR 

questo comando cercherà in C: \ myfolder e tutte le sottocartelle e sostituirà findSTR con replaceSTR

-r significa processare le sottocartelle in modo ricorsivo.

peto è veramente facile e veloce