Emacs hl-line: cambia localmente il colore

Question

Normalmente lascio la linea hl assumere una tonalità leggermente più scura dello sfondo corrente. Questo funziona bene nella modifica dei buffer. Tuttavia, in alcuni buffer, come l'agenda Organ e il buffer del gruppo Gnus, mi piacerebbe usare un colore più spiffy (al posto del cursore).

Per essere precisi vorrei cambiare il colore di hl-line nella gnus-hl-line senza influenzando il colore di hl-line in altri buffer.

(add-hook 'gnus-summary-mode-hook 'gnus-hl-line) 
(add-hook 'gnus-group-mode-hook 'gnus-hl-line) 

(defun gnus-hl-line() 
    (hl-line-mode 1) 
    (set (make-local-variable 'line-move-visual) nil) 
    (setq cursor-type nil)) 

Grazie,

soluzione finale utilizzando il suggerimento di Phil. Utilizza la linea hl neutrale per la maggior parte del tempo, ma a volte una linea hl in grassetto è apprezzabile, ad es. in agenda Gnus e Org

;; From emacs-wiki: 
(defun shade-color (intensity) 
    "print the #rgb color of the background, dimmed according to intensity" 
    (interactive "nIntensity of the shade : ") 
    (apply 'format "#%02x%02x%02x" 
     (mapcar (lambda (x) 
        (if (> (lsh x -8) intensity) 
         (- (lsh x -8) intensity) 
        0)) 
       (color-values (cdr (assoc 'background-color (frame-parameters))))))) 

;; Default hl 
(global-hl-line-mode t) 
(make-variable-buffer-local 'global-hl-line-mode) 
(set-face-background hl-line-face (shade-color 08)) 

(defface hl-line-highlight-face 
    '((t :inherit highlight)) 
    "Face for highlighting the current line with `hl-line-fancy-highlight'." 
    :group 'hl-line) 

(defun hl-line-fancy-highlight() 
    (set (make-local-variable 'hl-line-face) 'hl-line-highlight-face) 
    ;; (set (make-local-variable 'line-move-visual) nil) 
    ;; (set (make-local-variable 'cursor-type) nil) 
    (setq global-hl-line-mode nil) 
    (hl-line-mode)) 

(add-hook 'org-agenda-mode-hook 'hl-line-fancy-highlight) 
(add-hook 'gnus-summary-mode-hook 'hl-line-fancy-highlight) 
(add-hook 'gnus-group-mode-hook 'hl-line-fancy-highlight) 

Answer 1

hl-line-face è una variabile contenente la faccia da utilizzare per hl-line-mode, così possiamo rendere tale variabile buffer locale di queste modalità, e assegnare un nuovo volto personalizzato.

È possibile creare un nuovo volto come questo:

(defface gnus-hl-line 
    '((t :inherit hl-line)) 
    "Face for highlighting the current line with `gnus-hl-line'." 
    :group 'hl-line) 

e personalizzarlo con Mxcustomize-faceRETgnus-hl-lineRET

Poi aggiungere questo nella funzione gnus-hl-line (prima di chiamare hl-line-mode sembrerebbe più sensato).

(set (make-local-variable 'hl-line-face) 'gnus-hl-line)