Come ottenere le code di sequenza clojure

Question

ho sequenza in clojure di Theem

(1 2 3 4) 

come posso ottenere tutte le code di sequenza come

((1 2 3 4) (2 3 4) (3 4) (4)()) 

Answer 1

Un altro modo per ottenere tutte le code è quello di utilizzare la funzione reductions.

user=> (def x '(1 2 3 4)) 
#'user/x 
user=> (reductions (fn [s _] (rest s)) x x) 
((1 2 3 4) (2 3 4) (3 4) (4)()) 
user=> 

Answer 2

Ecco un modo.

user=> (def x [1 2 3 4]) 
#'user/x 
user=> (map #(drop % x) (range (inc (count x)))) 
((1 2 3 4) (2 3 4) (3 4) (4)()) 

Answer 3

Se si vuole fare questo con le funzioni di più alto livello, penso iterate avrebbe funzionato bene qui:

(defn tails [xs] 
    (concat (take-while seq (iterate rest xs)) '(())) 

Tuttavia, credo che in questo caso sarebbe più pulito per solo scrivere con lazy-seq:

(defn tails [xs] 
    (if-not (seq xs) '(()) 
    (cons xs (lazy-seq (tails (rest xs)))))) 

Answer 4

Un modo per farlo è

(defn tails [coll] 
    (take (inc (count coll)) (iterate rest coll))) 

Answer 5

(defn tails 
    [s] 
    (cons s (if-some [r (next s)] 
      (lazy-seq (tails r)) 
      '(())))) 

Answer 6

Yippee! Un altro:

(defn tails [coll] 
    (if-let [s (seq coll)] 
     (cons coll (lazy-seq (tails (rest coll)))) 
     '(()))) 

questo è davvero solo quello reductions fa sotto il cofano. La migliore risposta, a proposito, è ez121sl's.