Esiste una classe derivata effettiva in runtime in Perl?

Question

Sto cercando in Perl OO (nuovo in Perl). Ho creato un esempio di gerarchia di banale: classe
principale: classe

#!usr/bin/perl 
use strict; 
use warnings; 

package Objs::Employee; 

my $started; 

sub new { 
    my ($class) = @_; 
    my $cur_time = localtime; 
    my $self = { 
     started => $cur_time, 
    }; 
    print "Time: $cur_time \n"; 
    bless $self; 
} 

sub get_started { 
    my ($class) = @_; 
    return $class->{started}; 
} 

sub set_started { 
    my ($class, $value) = @_; 
    $class->{started} = $value; 
} 

1; 

bambini:

#!/usr/bin/perl 
package Objs::Manager; 
use strict; 
use warnings; 

use base qw (Objs::Employee); 

my $full_name; 

sub new { 
    my ($class, $name) = @_; 
    my $self = $class->SUPER::new(); 
    $self->{full_name} = $name; 
    return $self;  
} 

1; 

cerco di testarlo nel modo seguente:

#!/usr/bin/perl 
use strict; 
use warnings; 


use Objs::Manager; 

my $emp = Objs::Manager->new('John Smith'); 
use Data::Dumper; 
print Dumper($emp); 

Risultato:

Tempo: Dom Sep 29 12:56:29 2013

$VAR1 = bless({ 
       'started' => 'Sun Sep 29 12:56:29 2013', 
       'full_name' => 'John Smith' 
       }, 'Objs::Employee'); 

Domanda: Perché l'oggetto segnalato nel dump è un Obj :: Employee e non un Obj :: Manager?
Ho chiamato nuovo su un Manager.

Answer 1

Utilizzare sempre due argomenti per bless, come $class indica in quale pacchetto deve essere benedetto. Se si omette $class, viene utilizzato il pacchetto corrente.

bless $self, $class; 

uscita

$VAR1 = bless({ 
      'started' => 'Sun Sep 29 13:24:26 2013', 
      'full_name' => 'John Smith' 
      }, 'Objs::Manager'); 

Da perldoc -f bless:

Utilizzare sempre la versione a due argomenti se una classe derivata potrebbe ereditare la funzione di fare la benedizione