Conversione del valore di tipo <T> in Variant, è possibile?

Question

Ecco un frammento che mostra quello che sto cercando di realizzare:

type 
    TMyObject<T> = class (TObject) 
    function GetVarType(Value: T): TVarType; 
    end; 


function TMyObject<T>.GetVarType(Value: T): TVarType; 
var 
    TmpValue: Variant; 
begin 
    TmpValue := Variant(Value); //Invalid typecast 
    Result := VarType(TmpValue); 
end; 

So che al di sopra suddetto approccio con typecast è ingenuo, ma spero che si ottiene l'idea. Vorrei sostituirlo con un meccanismo di conversione.

TMyObject sarà sempre di tipo semplice come Integer, String, Single, Double.

Lo scopo di tale conversione è che la funzione VarType mi dà costante integer per ogni tipo semplice che posso memorizzare altrove.

Mi piacerebbe sapere se tale conversione è possibile?

Grazie per il vostro tempo.

Answer 1

È possibile utilizzare l'RTTI per ottenere queste informazioni, basta controllare il valore della proprietà TTypeInfo.Kind:

controllare questo codice di esempio

{$APPTYPE CONSOLE} 

uses 
    TypInfo, 
    Variants, 
    Generics.Collections, 
    SysUtils; 

type 
    TMyObject<T> = class (TObject) 
    function GetVarType(Value: T): TVarType; 
    end; 


function TMyObject<T>.GetVarType(Value: T): TVarType; 
begin 
    Case PTypeInfo(TypeInfo(T))^.Kind of 
    tkInteger : Result:=varInteger; 
    tkFloat : Result:=varDouble; 
    tkString : Result:=varString; 
    tkUString : Result:=varUString; 
    //add more types here 
    End; 
end; 

Var 
    LObj : TMyObject<Integer>; 
begin 
    try 
    Writeln(VarTypeAsText(TMyObject<Integer>.Create.GetVarType(5))); 
    Writeln(VarTypeAsText(TMyObject<String>.Create.GetVarType('Test'))); 
    except 
    on E: Exception do 
     Writeln(E.ClassName, ': ', E.Message); 
    end; 
    Readln; 
end. 

questo tornerà

Integer 
UnicodeString 

Answer 2

Non riesco a vedere come sia possibile farlo con i generici. Il compilatore deve sapere che un'istanza di tipo può essere assegnata a un Variant per qualsiasi possibile T. Non c'è modo per te di dire che il compilatore è possibile.

Se questo fosse un modello come in C++, sarebbe banale.

Answer 3

Grazie ragazzi per le tue risposte:

Come @RRUZ hanno dimostrato che è possibile le (intendo non un severo controllo ma estraendo il tipo di dati). Stavo lavorando da solo in attesa di una risposta e ho trovato una soluzione più generica.

Così sto postulando qui:

type 
    TMyObject<T> = class (TObject) 
    function GetVarType(Value: T): TVarType; 
    end; 


function TMyObject<T>.GetVarType(Value: T): TVarType; 
begin 
    Result := GetTypeData(TypeInfo(T)).varType; 
end; 

Ancora una volta grazie!

Answer 4

E 'banalmente risolvibile in Delphis con RTTI avanzato (2010 e successivi). Peccato che si è limitato al 2009 :(

function TMyObject<T>.GetVarType(Value: T): TVarType; 
begin 
    Result := VarType(TValue.From<T>(Value).AsVariant); 
end; 

Questo funziona solo per i tipi semplici, ma che era un vincolo specificato nella domanda.