subroutine di script batch: passaggio di argomenti

Question

La mia comprensione è che per ottenere la data da un file passato in una subroutine come argomento, è necessario reimpostare tale argomento come variabile all'interno della subroutine. È corretto? Questo non mi ha fatto, quindi mi chiedo se non capisco completamente cosa sta succedendo. Posso usare l'argomento passato in praticamente qualsiasi altro codice di subroutine eccetto per l'estrazione della data.

set setupEXE=setup.exe 

CALL :SUB_CheckCorrectDate %setupEXE% 
GOTO EOF 
::---------------------------------- 

:SUB_CheckCorrectDate 
set filename=%1% 

:: SUCCESSFUL 
for %%x in (%filename%) do set FileDate=%%~tx 
@For /F "tokens=1-3 delims=-/ " %%A in ('@echo %FileDate%') do @( 
Set file_Month=%%A 
Set file_Day=%%B 
Set file_Year=%%C 
) 

:: GET ERROR  
for %%x in (%1%) do set FileDate=%%~tx 
@For /F "tokens=1-3 delims=-/ " %%A in ('@echo %FileDate%') do @( 
Set file_Month=%%A 
Set file_Day=%%B 
Set file_Year=%%C 
)  

GOTO:EOF 

:: ------------------ 
:EOF 

Answer 1

Usa %1 per accedere al parametro, non %i%.

Le variabili argomento hanno gli stessi modificatori delle variabili FOR, quindi è possibile utilizzare %~t1.

Non è necessario eseguire un comando nel FOR/F. È più semplice elaborare una stringa letterale utilizzando in ("string").

Nessuna necessità per l'etichetta :EOF. Ogni script ha un implicito :eof. Mi piace usare invece exit /b.

@echo off 
setlocal 
set "setupEXE=setup.exe" 

call :SUB_CheckCorrectDate "%setupEXE%" 
exit /b 

::---------------------------------- 

:SUB_CheckCorrectDate 
set "filename=%~1" 
for /F "tokens=1-3 delims=-/ " %%A in ("%~t1") do ( 
    set "file_Month=%%A" 
    set "file_Day=%%B" 
    set "file_Year=%%C" 
) 
exit /b 

Answer 2

se si vuole seriamente di scrivere script batch, si dovrebbe prendere cura per la sintassi:

@echo off &setlocal 
set "setupEXE=setup.exe" 

CALL :SUB_CheckCorrectDate "%setupEXE%" 
GOTO EOF 
::---------------------------------- 

:SUB_CheckCorrectDate 
set "filename=%~1" 

:: SUCCESSFUL 
for %%x in ("%filename%") do set "FileDate=%%~tx" 
For /F "tokens=1-3 delims=-/ " %%A in ("%FileDate%") do ( 
    Set "file_Month=%%A" 
    Set "file_Day=%%B" 
    Set "file_Year=%%C" 
) 

:: GET ERROR  
for %%x in ("%~1") do set "FileDate=%%~tx" 
For /F "tokens=1-3 delims=-/ " %%A in ("%FileDate%") do ( 
    Set "file_Month=%%A" 
    Set "file_Day=%%B" 
    Set "file_Year=%%C" 
)  

GOTO:EOF 

:: ------------------ 
: