Come contare il numero di occorrenze di un certo carattere nella stringa?

Question

Come posso contare il numero di occorrenze di un certo carattere in una stringa in Delphi?

Ad esempio, si supponga di aver il seguente stringa e desidero contare il numero di virgole in esso:

S := '1,2,3'; 

Poi vorrebbe avere 2 come risultato.

Answer 1

È possibile utilizzare questa semplice funzione:

function OccurrencesOfChar(const S: string; const C: char): integer; 
var 
    i: Integer; 
begin 
    result := 0; 
    for i := 1 to Length(S) do 
    if S[i] = C then 
     inc(result); 
end; 

Answer 2

E per chi preferisce il ciclo enumeratore nelle versioni di Delphi moderne (non meglio rispetto alla soluzione accettata da Andreas, solo una soluzione alternativa):

function OccurrencesOfChar(const ContentString: string; 
    const CharToCount: char): integer; 
var 
    C: Char; 
begin 
    result := 0; 
    for C in ContentString do 
    if C = CharToCount then 
     Inc(result); 
end; 

Answer 3

Questo può fare il lavoro per se non stai manipolazione testo di grandi dimensioni

...

uses RegularExpressions; 

...

function CountChar(const s: string; const c: char): integer; 
begin 
Result:= TRegEx.Matches(s, c).Count 
end; 

Answer 4

Anche se una risposta è già stata accettata, sto postando la funzione più generale di seguito perché lo trovo così elegante. Questa soluzione serve a contare le occorrenze di una stringa piuttosto che un carattere.

{ Returns a count of the number of occurences of SubText in Text } 
function CountOccurences(const SubText: string; 
          const Text: string): Integer; 
begin 
    Result := Pos(SubText, Text); 
    if Result > 0 then 
    Result := (Length(Text) - Length(StringReplace(Text, SubText, '', [rfReplaceAll]))) div Length(subtext); 
end; { CountOccurences } 

Answer 5

È possibile utilizzare il beneficio della funzione StringReplace come:

function OccurencesOfChar(ContentString:string; CharToCount:char):integer; 
begin 
    Result:= Length(ContentString)-Length(StringReplace(ContentString, CharToCount,'', [rfReplaceAll, rfIgnoreCase])); 
end;