Sostituire una nuova riga in TSQL

Question

Vorrei sostituire (o rimuovere) un carattere di nuova riga in una stringa TSQL. Qualche idea?

L'ovvio

REPLACE(@string, CHAR(13), '') 

proprio non lo farà ...

Answer 1

In realtà una nuova riga in un comando SQL o una stringa di script può essere qualsiasi di CR, LF o CR + LF. Per farli tutti, avete bisogno di qualcosa di simile:

SELECT REPLACE(REPLACE(@str, CHAR(13), ''), CHAR(10), '') 

Answer 2

REPLACE(@string, CHAR(13) + CHAR(10), '') 

Answer 3

La nuova riga in T-SQL è rappresentato da CHAR (13) & CHAR (10) (Carriage ritorno + Avanzamento riga). Di conseguenza, è possibile creare un'istruzione REPLACE con il testo con cui si desidera sostituire la nuova riga.

Answer 4

Per fare quello che la maggior parte la gente vorrebbe, creare un segnaposto che non è una rottura carattere riga effettiva. Quindi è possibile combinare gli approcci per:

REPLACE(REPLACE(REPLACE(MyField, CHAR(13) + CHAR(10), 'something else'), CHAR(13), 'something else'), CHAR(10), 'something else') 

In questo modo si sostituisce solo una volta. L'approccio di:

REPLACE(REPLACE(MyField, CHAR(13), ''), CHAR(10), '') 

funziona grande se si vuole solo sbarazzarsi dei caratteri CRLF, ma se si vuole un segnaposto, come ad esempio
o qualcosa del genere, quindi il primo approccio è un po 'più accurata.

Answer 5

io possa essere un anno di ritardo alla festa, ma lavorare su query & MS-SQL ogni giorno, e mi sono stancato delle funzioni built-in LTRIM() & RTRIM() (e avendo sempre di chiamarli insieme), e di non rilevare i dati "sporchi" che avevano newline alla fine, quindi ho deciso che era giunto il momento di implementare una funzione di TRIM migliore. Mi piacerebbe ricevere il feedback dei colleghi!

responsabilità: questo in realtà rimuove (sostituisce con un singolo spazio bianco) forme estese di spazi bianchi (tab, line-feed, ritorno a capo, etc.), quindi è stato rinominato come "CleanAndTrim" dal mio originale risposta. L'idea qui è che la tua stringa non ha caratteri extra-speciali all'interno di esso, e quindi se non si verificano in testa/coda, dovrebbero essere sostituiti con uno spazio semplice. Se hai memorizzato intenzionalmente tali caratteri nella stringa (ad esempio, la colonna di dati su cui stai per eseguirla), NON FARLO! Migliora questa funzione o scrivi la tua che rimuove letteralmente quei caratteri dai punti finali della stringa, non dal 'corpo'.

Ok, ora che la dichiarazione di non responsabilità è aggiornata, ecco il codice.

-- ============================================= 
-- Description: TRIMs a string 'for real' - removes standard whitespace from ends, 
-- and replaces ASCII-char's 9-13, which are tab, line-feed, vert tab, 
-- form-feed, & carriage-return (respectively), with a whitespace 
-- (and then trims that off if it's still at the beginning or end, of course). 
-- ============================================= 
CREATE FUNCTION [fn_CleanAndTrim] (
     @Str nvarchar(max) 
) 
RETURNS nvarchar(max) AS 
BEGIN 
     DECLARE @Result nvarchar(max) 

     SET @Result = LTRIM(RTRIM(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(
       LTRIM(RTRIM(@Str)), CHAR(9), ' '), CHAR(10), ' '), CHAR(11), ' '), CHAR(12), ' '), CHAR(13), ' '))) 

     RETURN @Result 
END 

Cheers!

Un'altra responsabilità: Il tipico linea-break Windows è CR + LF, quindi se la stringa contiene quelli, si sarebbe finito la loro sostituzione con spazi "doppie".

UPDATE 2016: Una nuova versione che ti dà la possibilità di sostituire i caratteri speciali-spazio bianco con altri personaggi della vostra scelta! Ciò include anche il commento e il work-around per l'accoppiamento di Windows CR + LF, cioè sostituisce quella specifica coppia di caratteri con una sostituzione singola.

IF OBJECT_ID('dbo.fn_CleanAndTrim') IS NULL 
    EXEC ('CREATE FUNCTION dbo.fn_CleanAndTrim() RETURNS INT AS BEGIN RETURN 0 END') 
GO 
-- ============================================= 
-- Author: Nate Johnson 
-- Source: http://stackoverflow.com/posts/24068265 
-- Description: TRIMs a string 'for real' - removes standard whitespace from ends, 
-- and replaces ASCII-char's 9-13, which are tab, line-feed, vert tab, form-feed, 
-- & carriage-return (respectively), with a whitespace or specified character(s). 
-- Option "@PurgeReplaceCharsAtEnds" determines whether or not to remove extra head/tail 
-- replacement-chars from the string after doing the initial replacements. 
-- This is only truly useful if you're replacing the special-chars with something 
-- **OTHER** than a space, because plain LTRIM/RTRIM will have already removed those. 
-- ============================================= 
ALTER FUNCTION dbo.[fn_CleanAndTrim] (
    @Str NVARCHAR(MAX) 
    , @ReplaceTabWith NVARCHAR(5) = ' ' 
    , @ReplaceNewlineWith NVARCHAR(5) = ' ' 
    , @PurgeReplaceCharsAtEnds BIT = 1 
) 
RETURNS NVARCHAR(MAX) AS 
BEGIN 
    DECLARE @Result NVARCHAR(MAX) 

    --The main work (trim & initial replacements) 
    SET @Result = LTRIM(RTRIM(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(
     LTRIM(RTRIM(@Str)) --Basic trim 
     , NCHAR(9), @ReplaceTabWith), NCHAR(11), @ReplaceTabWith) --Replace tab & vertical-tab 
     , (NCHAR(13) + NCHAR(10)), @ReplaceNewlineWith) --Replace "Windows" linebreak (CR+LF) 
     , NCHAR(10), @ReplaceNewlineWith), NCHAR(12), @ReplaceNewlineWith), NCHAR(13), @ReplaceNewlineWith))) --Replace other newlines 

    --If asked to trim replacement-char's from the ends & they're not both whitespaces 
    IF (@PurgeReplaceCharsAtEnds = 1 AND NOT (@ReplaceTabWith = N' ' AND @ReplaceNewlineWith = N' ')) 
    BEGIN 
     --Purge from head of string (beginning) 
     WHILE (LEFT(@Result, DATALENGTH(@ReplaceTabWith)/2) = @ReplaceTabWith) 
      SET @Result = SUBSTRING(@Result, DATALENGTH(@ReplaceTabWith)/2 + 1, DATALENGTH(@Result)/2) 

     WHILE (LEFT(@Result, DATALENGTH(@ReplaceNewlineWith)/2) = @ReplaceNewlineWith) 
      SET @Result = SUBSTRING(@Result, DATALENGTH(@ReplaceNewlineWith)/2 + 1, DATALENGTH(@Result)/2) 

     --Purge from tail of string (end) 
     WHILE (RIGHT(@Result, DATALENGTH(@ReplaceTabWith)/2) = @ReplaceTabWith) 
      SET @Result = SUBSTRING(@Result, 1, DATALENGTH(@Result)/2 - DATALENGTH(@ReplaceTabWith)/2) 

     WHILE (RIGHT(@Result, DATALENGTH(@ReplaceNewlineWith)/2) = @ReplaceNewlineWith) 
      SET @Result = SUBSTRING(@Result, 1, DATALENGTH(@Result)/2 - DATALENGTH(@ReplaceNewlineWith)/2) 
    END 

    RETURN @Result 
END 
GO 

Answer 6

Se si dispone di un problema in cui si desidera rimuovere finali caratteri, si può provare questo:

WHILE EXISTS 
(SELECT * FROM @ReportSet WHERE 
    ASCII(right(addr_3,1)) = 10 
    OR ASCII(right(addr_3,1)) = 13 
    OR ASCII(right(addr_3,1)) = 32) 
BEGIN 
    UPDATE @ReportSet 
    SET addr_3 = LEFT(addr_3,LEN(addr_3)-1) 
    WHERE 
    ASCII(right(addr_3,1)) = 10 
    OR ASCII(right(addr_3,1)) = 13 
    OR ASCII(right(addr_3,1)) = 32 
END 

Questo ha risolto un problema che ho avuto con gli indirizzi in cui una procedura creato un campo con un numero fisso di linee, anche se quelle linee erano vuote. Per risparmiare spazio nel mio rapporto SSRS, li ho abbattuti.

Answer 7

Se il tipo di dati della colonna è 'testo' allora si ottiene un messaggio di errore come

Msg 8116, livello 16, stato 1, riga 2 argomento di tipo di dati di testo è valido per l'argomento 1 di sostituire la funzione.

In questo caso è necessario lanciare il testo come nvarchar e quindi sostituire

SELECT REPLACE(REPLACE(cast(@str as nvarchar(max)), CHAR(13), ''), CHAR(10), '') 

Answer 8

Se si dispone di avere procedura aperta con l'utilizzo di sp_helptext poi basta copiare tutto il testo nella nuova query SQL e premere Ctrl + h il pulsante usa l'espressione regolare per sostituire e inserisce^\ n nel campo di ricerca sostituisce con lo spazio vuoto. per maggiori dettagli controlla l'immagine. enter image description here