Risolvere la lettera di unità di Windows in un percorso (subst e rete)

Question

Mi chiedo se esiste un modo universale per risolvere un percorso utilizzando una lettera di unità (come X:\foo\bar.txt) nel suo percorso UNC equivalente, che potrebbe essere uno dei seguenti:

• X:\foo\bar.txt se X: è un'unità reale (cioè hard disk, chiavetta USB, ecc)
• \\server\share\foo\bar.txt se X: è un'unità di rete montata su \\server\share
• C:\xyz\foo\bar.txt se X: è il risultato di un SUBST comando di mappatura X: a C:\xyz

So che ci sono soluzioni parziali che sarà:

1. risolvere un'unità di rete (si veda ad esempio question 556649 che si basa su WNetGetUniversalName)

2. Risolvere il SUBST lettera di unità (vedere QueryDosDevice che funziona come previsto, ma non restituisce percorsi UNC per elementi quali unità locali o unità di rete).

Mi manca un modo semplice per implementare questa risoluzione di lettera di unità in Win32? O devo davvero pasticciare sia con lo WNetGetUniversalName sia con lo QueryDosDevice per ottenere ciò di cui ho bisogno?

Answer 1

Sì, è necessario risolvere la lettera di unità in modo indipendente.

WNetGetUniversalName() si avvicina, ma funziona solo per lettere di unità mappate a condivisioni UNC effettive, il che non è sempre il caso. Non esiste una singola funzione API che faccia tutto il lavoro per te.

Answer 2

Ecco un batch per tradurre lettere di unità in percorsi UNC o invertire percorsi substed. Non è garantito che funzioni comunque.

Esempio di utilizzo: script.cmd echo Z: Y: W:

@echo off 
:: u is a variable containing all arguments of the current command line 
set u=%* 

:: enabledelayedexpansion: exclamation marks behave like percentage signs and enable 
:: setting variables inside a loop 
setlocal enabledelayedexpansion 

:: parsing result of command subst 
:: format: I: => C:\foo\bar 
:: variable %G will contain I: and variable H will contain C:\foo\bar 
for /f "tokens=1* delims==> " %%G IN ('subst') do (
set drive=%%G 
:: removing extra space 
set drive=!drive:~0,2! 
:: expanding H to a short path in order not to break the resulting command line 
set subst=%%~sfH 
:: replacing command line. 
call set u=%%u:!drive!=!subst!%% 
) 

:: parsing result of command net use | findstr \\ ; this command is not easily tokenized because not always well-formatted 
:: testing whether token 2 is a drive letter or a network path. 
for /f "tokens=1,2,3 delims= " %%G IN ('net use ^| findstr \\') do (
set tok2=%%H 
if "!tok2:~0,2!" == "\\" (
    set drive=%%G 
    set subst=%%H 
) else (
    set drive=%%H 
    set subst=%%I 
) 
:: replacing command line. 
call set u=%%u:!drive!=!subst!%% 
) 

call !u!