Come creare un discendente TStringList con il proprietario che libererà automaticamente TStringList?

Question

Spero di creare una sorta di "TOwnedStringList" (nome di classe è una finzione) che ho potuto costruire come:

sl := TOwnedStringList.Create(Self); 
sl.Sorted := True; 
sl.Duplicates := dupIgnore; 
sl.Add(...); 
// etc... 

Dove Self potrebbe essere una forma (per esempio), in modo che il proprietario auto libera l'elenco delle stringhe. Voglio essere in grado di evitare di chiamare me stesso sl.Free.

è possibile?

Answer 1

che sta per essere un po 'disordinato. Dovresti fare qualcosa di simile.

type 
    TOwnerComponent = class(TComponent) 
    private 
    FOwnedObject: TObject; 
    public 
    constructor Create(Owner: TComponent; OwnedObject: TObject); 
    destructor Destroy; override; 
    end; 

    TOwnedStringList = class(TStringList) 
    private 
    FOwner: TOwnerComponent; 
    public 
    constructor Create(Owner: TComponent); 
    destructor Destroy; override; 
    end; 

{ TOwnerComponent } 

constructor TOwnerComponent.Create(Owner: TComponent; OwnedObject: TObject); 
begin 
    inherited Create(Owner); 
    FOwnedObject := OwnedObject; 
end; 

destructor TOwnerComponent.Destroy; 
begin 
    FOwnedObject.Free; 
    inherited; 
end; 

{ TOwnedStringList } 

constructor TOwnedStringList.Create(Owner: TComponent); 
begin 
    inherited Create; 
    if Assigned(Owner) then 
    FOwner := TOwnerComponent.Create(Owner, Self); 
end; 

destructor TOwnedStringList.Destroy; 
begin 
    if Assigned(FOwner) and not (csDestroying in FOwner.ComponentState) then 
    begin 
    FOwner.FOwnedObject := nil; 
    FOwner.Free; 
    end; 
    inherited; 
end; 

In sostanza si crea un'istanza di TOwnerComponent che è di proprietà della Owner che si passa a TOwnedStringList.Create. Quando ciò Owner muore, distrugge la TOwnerComponent che a sua volta distrugge il vostro elenco di stringhe.

Il codice è resiliente ad una esplicita Free essere chiamato nella lista di stringhe.