Tipi di linea Gnuplot

Question

Come si disegnano diversi tipi di linee su gnuplot? Devo disegnare colori diversi. Il mio script unisce diversi file e penso che sia il motivo per cui le linee non sono trattini. Solo due su quattro sono tratteggiati. Grazie Felipe

#!/usr/bin/gnuplot 

set grid 
set title 'Estado dos arquivos no BTRIM com peers de comportamento condicionado' 
set xlabel 'Tempo discreto' 
set ylabel 'Quantidade de arquivos' 
set style line 1 lc rgb '#0060ad' lt 1 lw 2 pi -1 ps 1.0 
set style line 2 lc rgb '#dd181f' lt 9 lw 2 pi -1 ps 1.0 
set style line 3 lc rgb '#29c524' lt 6 lw 2 pi -1 ps 1.0 
set style line 4 lc rgb '#7D72F9' lt 7 lw 2 pi -1 ps 1.0 
set style line 5 lc rgb '#000000' lt 8 lw 2 pi -1 ps 1.0 

set termoption dashed 
#set pointintervalbox 0 
#set boxwidth 0.1 
#set style fill solid 

plot '<paste ../00/StatisticNormal.txt ../01/StatisticNormal.txt ../02/StatisticNormal.txt ../03/StatisticNormal.txt ../04/StatisticNormal.txt ../05/StatisticNormal.txt ../06/StatisticNormal.txt ../07/StatisticNormal.txt ../08/StatisticNormal.txt ../09/StatisticNormal.txt' smooth unique with line ls 1 title 'Normais', \ 
'<paste ../00/StatisticVogue.txt ../01/StatisticVogue.txt ../02/StatisticVogue.txt ../03/StatisticVogue.txt ../04/StatisticVogue.txt ../05/StatisticVogue.txt ../06/StatisticVogue.txt ../07/StatisticVogue.txt ../08/StatisticVogue.txt ../09/StatisticVogue.txt' smooth unique with line ls 2 title 'na Moda', \ 
'<paste ../00/StatisticPopular.txt ../01/StatisticPopular.txt ../02/StatisticPopular.txt ../03/StatisticPopular.txt ../04/StatisticPopular.txt ../05/StatisticPopular.txt ../06/StatisticPopular.txt ../07/StatisticPopular.txt ../08/StatisticPopular.txt ../09/StatisticPopular.txt' smooth unique with line ls 3 title 'Populares', \ 
'<paste ../00/StatisticRarity.txt ../01/StatisticRarity.txt ../02/StatisticRarity.txt ../03/StatisticRarity.txt ../04/StatisticRarity.txt ../05/StatisticRarity.txt ../06/StatisticRarity.txt ../07/StatisticRarity.txt ../08/StatisticRarity.txt ../09/StatisticRarity.txt' smooth unique with line ls 4 title 'Raros' 

pause -1 

Answer 1

Fino alla versione 4.6

Il tipo cruscotto di un linestyle è data dalla linetype, che fa anche selezionare il colore della linea a meno che non esplicitamente impostare un altro con linecolor.

Tuttavia, il supporto per le linee tratteggiate dipende dal terminale selezionato:

1. Alcuni terminali non supportano linee tratteggiate, come png (utilizza libgd)
2. Altri terminali, come pngcairo, supporto linee tratteggiate , ma è disabilitato di default. Per abilitarlo, utilizzare set termoption dashed o set terminal pngcairo dashed ....
3. I modelli di trattino esatti differiscono tra i terminali. Vedere la definita linetype, utilizzare il comando test:

corsa

set terminal pngcairo dashed 
set output 'test.png' 
test 
set output 

dà:

che, il terminale postscript mostra diversi modelli precipitare:

set terminal postscript eps color colortext 
set output 'test.eps' 
test 
set output 

versione 5.0

A partire dalla versione 5.0 le seguenti modifiche relative alla tipi di linea, modelli cruscotto e colori delle linee vengono introdotti:

• un nuovo parametro dashtype è stato introdotto:

  Per ottenere i modelli di trattini predefiniti, utilizzare ad es

  plot x dashtype 2 
  

  È inoltre possibile specificare i modelli del precipitare personalizzato come

  plot x dashtype (3,5,10,5),\ 
      2*x dashtype '.-_' 
  

• Le opzioni del terminale dashed e solid vengono ignorati. Di default tutte le linee sono solide. Per cambiarli in tratteggiati, usa per es.

  set for [i=1:8] linetype i dashtype i 
  

• L'impostazione predefinita di colori di linea è stata modificata.È possibile scegliere tra tre diversi set di colori con set colorsequence default|podo|classic: