Per/F + Wmic + DOVE clausule + E clausule

Question

Solo per curiosità, questo comando:

wmic service where (name="themes" and state="running") get 

Come dovrebbe essere scritta insieme a un FOR in uno script?

Il codice qui sotto non funziona:

For /F %%a in (
    'wmic service where ^("name='themes'" and "state='running'"^) get' 
) do (
    echo %%a 
) 

Answer 1

@echo off 
For /F "usebackq delims=" %%a in (`wmic service where 'name^="themes" and state^="running"' get`) do (
    echo %%a 
) 

questo funziona per me.I've utilizzato usebackq possibilità di avere problemi con ' e alternativa sintassi wmic - ' invece di parentesi.

Answer 2

È possibile racchiudere il comando wmic completo in virgolette singole + doppie, quindi non c'è bisogno di sfuggire nulla

FOR /F "delims=" %%a in ('"wmic service where (name="themes" and state="running") get"') do (
    echo %%a 
) 

Answer 3

Ancora un'altra opzione :)

@echo off 
for /f "delims=" %%A in (
    'wmic service where "name='themes' and state='running'" get' 
) do for /f "delims=" %%B in ("%%A") do echo %%B 

complesso in cui le clausole devono essere o quotati o tra parentesi. L'extra interno ' non causa problemi con FOR/F.

Ho aggiunto un extra FOR/F per rimuovere il ritorno a capo indesiderato che viene aggiunto alla fine di ogni riga come un artefatto di FOR/F che converte l'output Unicode WMIC in ANSII. Senza il FOR/F aggiuntivo, vi è una riga aggiuntiva che consiste esclusivamente di un ritorno a capo che risulta in ECHO is off. alla fine.

Penso che preferisco la versione di jeb perché elimina la necessità di escape nell'intero comando, anche se probabilmente utilizzerei virgolette singole all'interno della clausola WHERE. Per esempio:

@echo off 
for /f "delims=" %%A in (
    '"wmic service where (name='themes' and state='running') get name, pathName"' 
) do for /f "delims=" %%B in ("%%A") do echo %%B 

Utilizzando la sintassi nel mio primo esempio di codice richiede sfuggire le virgole nella clausola GET:

@echo off 
for /f "delims=" %%A in (
    'wmic service where "name='themes' and state='running'" get name^, pathName' 
) do for /f "delims=" %%B in ("%%A") do echo %%B