Raytracing in OpenGL tramite compute shader

Question

Sto provando a eseguire un po 'di raytracing in OpenGL tramite lo shader di elaborazione e mi sono imbattuto in uno strano problema. Al momento voglio solo visualizzare una sfera senza sfumature. Il mio Compute Shader lancia un raggio per ogni pixel e si presenta così:

#version 430 
struct Sphere{ 
    vec4 position; 
    float radius; 
}; 

struct Ray{ 
    vec3 origin; 
    vec3 dir; 
}; 

uniform image2D outputTexture; 
uniform uint  width; 
uniform uint  height; 

float hitSphere(Ray r, Sphere s){ 

    float s_vv = dot(r.dir, r.dir); 
    float s_ov = dot(r.origin, r.dir); 
    float s_mv = dot(s.position.xyz, r.dir); 
    float s_mm = dot(s.position.xyz, s.position.xyz); 
    float s_mo = dot(s.position.xyz, r.origin); 
    float s_oo = dot(r.origin, r.origin); 

    float d = s_ov*s_ov-2*s_ov*s_mv+s_mv*s_mv-s_vv*(s_mm-2*s_mo*s_oo-s.radius*s.radius); 

    if(d < 0){ 
     return -1.0f; 
    } else if(d == 0){ 
     return (s_mv-s_ov)/s_vv; 
    } else { 
     float t1 = 0, t2 = 0; 
     t1 = s_mv-s_ov; 

     t2 = (t1-sqrt(d))/s_vv; 
     t1 = (t1+sqrt(d))/s_vv; 

     return t1>t2? t2 : t1 ; 
    } 
} 

layout (local_size_x = 16, local_size_y = 16, local_size_z = 1) in; 
void main(){ 
    uint x = gl_GlobalInvocationID.x; 
    uint y = gl_GlobalInvocationID.y; 

    if(x < 1024 && y < 768){ 
     float t = 0.0f; 
     Ray r = {vec3(0,0,0), vec3(width/2-x, height/2-y, 1000)}; 
     Sphere sp ={vec4(0, 0, 35, 1), 5.0f}; 

     t = hitSphere(r, sp); 

     if(t <= -0.001f){ 
      imageStore(outputTexture, ivec2(x, y), vec4(0.0, 0.0, 0.0, 1.0)); 
     } else { 
      imageStore(outputTexture, ivec2(x, y), vec4(0.0, 1.0, 0.0, 1.0)); 
     } 

     if(x == 550 && y == 390){ 
      imageStore(outputTexture, ivec2(x, y), vec4(1.0, 0.0, 0.0, 1.0)); 
     } 
    } 
} 

Quando eseguo l'applicazione ottengo la seguente immagine:

Ma quando ho eseguito lo stesso algoritmo sulla CPU ottengo la seguente immagine più convincente:

Innanzitutto pensavo di non aver inviato abbastanza gruppi di lavoro in modo che non tutti i pixel ricevessero la propria invocazione di shader computazionale, ma non è così. Come puoi vedere nell'immagine di rendering della GPU c'è un pixel rosso nel mezzo che è causato dalle ultime righe nello shader di calcolo. Questo può essere riprodotto per ogni altro pixel.

io uso una risoluzione di 1024x768 in questo momento e questo è come mi invio il mio Compute Shader:

#define WORK_GROUP_SIZE 16 
void OpenGLRaytracer::renderScene(int width, int height){ 
    glUseProgram(_progID); 

    glDispatchCompute(width/WORK_GROUP_SIZE, height/WORK_GROUP_SIZE,1); 

    glMemoryBarrier(GL_TEXTURE_FETCH_BARRIER_BIT); 
} 

Dov'è l'errore? Potrebbe esserci un problema con la precisione dei calcoli in virgola mobile?

Answer 1

L'errore è in questa linea:

Ray r = {vec3(0,0,0), vec3(width/2-x, height/2-y, 1000)}; 

Dal larghezza, altezza, xey sono variabili uint che avranno problemi quando la larghezza termine/2-x diventa negativ.

Questo risolve il problema:

Ray r = {vec3(0,0,0), vec3(float(width)/2.0f-float(x), float(height)/2.0f-float(y), 1000)};