qmake: opzioni di gestione per gcc e msvc

Question

Vorrei creare un file di progetto che funzionasse sia con msvc che con gcc.

Per le istanze, per ottimizzare la velocità si farebbe cl /O2 e g++ -O3.

Ma non so come dire al file di progetto per fare la differenza. Vorrei qualcosa di simile:

msvc:QMAKE_CXXFLAGS_RELEASE += /O2 /openmp /arch:AVX 
else:QMAKE_CXXFLAGS_RELEASE += -O3 -march=native -fopenmp -D_GLIBCXX_PARALLEL 

che non funziona purtroppo.

Un altro modo sarebbe quello di modificare gli mkspec e raggruppare quelli nuovi con la mia app, ma non è molto portabile. Grazie!

Answer 1

Jean, per essere precisi, è necessario utilizzare questo in base alla descrizione:

msvc:QMAKE_CXXFLAGS_RELEASE += /O2 /openmp /arch:AVX 
gcc:QMAKE_CXXFLAGS_RELEASE += -O3 -march=native -fopenmp -D_GLIBCXX_PARALLEL 

Answer 2

Ecco un file di progetto che ho utilizzato. Funziona per Windows (msvc) e Linux (GCC)

QT = core gui widgets 

HEADERS += \ 
    render.h 

SOURCES += \ 
    main.cpp \ 
    render.cpp 

QMAKE_CXXFLAGS_RELEASE -= -O 
QMAKE_CXXFLAGS_RELEASE -= -O1 
QMAKE_CXXFLAGS_RELEASE -= -O2 

win32 { # For Windows 
    QMAKE_CXXFLAGS += -openmp 
    QMAKE_CXXFLAGS += -arch:AVX 
    QMAKE_CXXFLAGS += -D "_CRT_SECURE_NO_WARNINGS" 
    QMAKE_CXXFLAGS_RELEASE *= -O2 
} 

linux { # For Linux 
    QMAKE_CXXFLAGS += -fopenmp 
    QMAKE_LFLAGS += -fopenmp 
    QMAKE_CXXFLAGS += -mavx 
    QMAKE_CXXFLAGS_RELEASE *= -O3 
}