Partizionare una tabella per ottenere intervalli di date

Question

Ho una tabella di cronologia per un utente e sto cercando di trovare intervalli di date in cui l'utente ha un nome utente specifico. La tabella è una tabella di controllo che viene riempita da un trigger, pertanto contiene voci ogni volta che viene apportata una modifica a un utente, non solo al nome utente. Posso fare questo per ottenere l'intervallo di date per ogni riga:

CREATE TABLE #LoginHistory 
(
    LoginHistoryID INT IDENTITY(1,1), 
    LoginID INT, 
    Username VARCHAR(32), 
    StartDate DATETIME 
) 

INSERT INTO #LoginHistory (LoginID, Username, StartDate) VALUES 
(1, 't', '2016-01-01'), 
(1, 't', '2016-01-02'), 
(1, 't', '2016-01-04'), 
(1, 'test', '2016-01-05'), 
(2, 't', '2016-01-08'), 
(2, 'tom', '2016-01-09'), 
(1, 'test', '2016-01-15'), 
(1, 't', '2016-02-01') 

SELECT 
    LoginID, 
    Username, 
    StartDate, 
    EndDate = LEAD(StartDate) OVER (PARTITION BY LoginID ORDER BY StartDate ASC) 
FROM #LoginHistory 
WHERE LoginID = 1 
ORDER BY StartDate ASC 

DROP TABLE #LoginHistory 

uscita:

LoginID Username StartDate    EndDate 
1  t   2016-01-01 00:00:00.000 2016-01-02 00:00:00.000 
1  t   2016-01-02 00:00:00.000 2016-01-04 00:00:00.000 
1  t   2016-01-04 00:00:00.000 2016-01-05 00:00:00.000 
1  test  2016-01-05 00:00:00.000 2016-01-15 00:00:00.000 
1  test  2016-01-15 00:00:00.000 2016-02-01 00:00:00.000 
1  t   2016-02-01 00:00:00.000 NULL 

Tuttavia, quello che mi piacerebbe davvero fare è di crollare ogni durata nome utente in modo che ci sia una riga per intervallo di date in cui un utente ha mantenuto un nome utente. Fondamentalmente, sto cercando questa uscita:

LoginID Username StartDate    EndDate 
1  t   2016-01-01 00:00:00.000 2016-01-05 00:00:00.000 
1  test  2016-01-05 00:00:00.000 2016-02-01 00:00:00.000 
1  t   2016-02-01 00:00:00.000 NULL 

Come dovrei fare per comprimere queste righe correttamente?

Answer 1

È possibile utilizzare la seguente query:

SELECT LoginID, 
     Username, 
     MIN(StartDate) AS StartDate, 
     MAX(EndDate) AS EndDate 
FROM (
    SELECT 
     LoginID, 
     Username, 
     StartDate, 
     EndDate = LEAD(StartDate) OVER (PARTITION BY LoginID 
             ORDER BY StartDate ASC), 
     ROW_NUMBER() OVER (ORDER BY StartDate) - 
     ROW_NUMBER() OVER (PARTITION BY LoginID, Username 
         ORDER BY StartDate) AS grp 
    FROM #LoginHistory 
    WHERE LoginID = 1) AS t 
GROUP BY LoginID, Username, grp 
ORDER BY StartDate ASC 

grp aiuta a identificare consecutivi righe aventi le stesse LoginID, Username valori.